正三角形と正六角形②

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  noLoop();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeTriangleVector(); // 三角格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP6(); // タイルを生成
  drawTiling(); // タイリングを描画
}

// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 3);
}

// 三角格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 3][row_num + 1];
  for (int i = 0; i < col_num + 3; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], (i-3) * scalar * sqrt(7.0)/2.0 ); 
      v.add(PVector.mult(base[1], j * scalar * sqrt(7.0)/2.0 ) );
      lattice[i][j] = v;
    }
  }
}

// 五角形を生成する関数（基本図形）
PShape makePentagon(){
  
  PVector[] v = new PVector[5]; // 五角形の頂点
  float theta = acos(5.0 / 2.0 / sqrt(7.0) );
  v[0] = new PVector(0.0,0.0);
  v[1] = PVector.fromAngle( -radians( 120.0 ) - theta ).mult( scalar );
  v[4] = PVector.fromAngle( radians( 180.0 ) - theta ).mult( scalar );
  v[3] = v[4].copy().add( v[1].copy() );
  v[2] = v[3].copy().add( v[1].copy().rotate( radians(90.0) ).mult( 1.0/sqrt(3.0) ) );

  PShape pentagon = createShape(GROUP);
  // 正六角形の一部となる正三角形を描く
  fill(0,0,255);
  noStroke();
  PShape tri = createShape();
  tri.beginShape(); 
  tri.vertex(v[0].x, v[0].y);
  tri.vertex(v[1].x, v[1].y);
  tri.vertex(v[4].x, v[4].y);
  tri.endShape(CLOSE);
  pentagon.addChild(tri);
  
  // 正三角形を描く
  fill(0,255,0);
  stroke(0,0,0);
  tri = createShape();
  tri.beginShape(); 
  tri.vertex(v[1].x, v[1].y);
  tri.vertex(v[3].x, v[3].y);
  tri.vertex(v[4].x, v[4].y);
  tri.endShape(CLOSE);
  pentagon.addChild(tri);

  // 正三角形の一部となる二等辺三角形を描く
  fill(0,0,255);
  noStroke();
  tri = createShape();
  tri.beginShape(); 
  tri.vertex(v[1].x, v[1].y);
  tri.vertex(v[2].x, v[2].y);
  tri.vertex(v[3].x, v[3].y);
  tri.endShape(CLOSE);
  pentagon.addChild(tri);
 
  return pentagon;
}

// タイルを生成する関数
void makeTileP6(){
  tile = createShape(GROUP); // PShapeのグループを作る

  for (int i=0; i<6; i++){
    PShape pentagon = makePentagon(); // 変形した五角形の生成
    pentagon.rotate(PI * i / 3); // 60度回転
    tile.addChild(pentagon); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }
}