正三角形と正六角形①

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  noLoop();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeTriangleVector(); // 三角格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP6M(); // タイルを生成
  drawTiling(); // タイリングを描画
}

// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 3);
}

// 三角格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 5][row_num + 1];
  for (int i = 0; i < col_num + 5; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], (i-4) * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x, v.y); 
    }
  }
}

// 直角三角形を生成する関数（基本図形）
PShape makeRightTriangle(){

  PVector[] v = new PVector[3]; // 直角三角形の頂点
  
  v[0] = new PVector(0.0,0.0);
  v[1] = PVector.fromAngle(PI / 6.0);
  v[1].mult(2.0 * scalar / sqrt(3.0));  
  v[2] = new PVector(1.0,0.0);
  v[2].mult(scalar);

  PVector v_middle = v[1].copy().mult(3.0/4.0);
  PShape rightTri = createShape(GROUP);
  
  // 内部の直角三角形（大）を描く
  fill(128,0,0);
  noStroke();
  PShape rightTri1 = createShape();  
  rightTri1.beginShape(TRIANGLES); 
  rightTri1.vertex(v[0].x, v[0].y);
  rightTri1.vertex(v_middle.x, v_middle.y);
  rightTri1.vertex(v[2].x, v[2].y);
  rightTri1.endShape();
  rightTri.addChild(rightTri1);
  
  // 内部の直角三角形（小）を描く
  fill(255,255,128);
  PShape rightTri2 = createShape();  
  rightTri2.beginShape(TRIANGLES); 
  rightTri2.vertex(v[2].x, v[2].y);
  rightTri2.vertex(v_middle.x, v_middle.y);
  rightTri2.vertex(v[1].x, v[1].y);
  rightTri2.endShape();
  rightTri.addChild(rightTri2);

  return rightTri;
}

// タイルを生成する関数
void makeTileP6M(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for (int i=0; i<6; i++){
    PShape positiveTri = createShape(GROUP); // 直角三角形を2つ合わせて正三角形を生成
    for (int j=0; j<2; j++){
      PShape rightTri = makeRightTriangle(); // 直角三角形の生成
      rightTri.scale(1, pow(-1, j)); // x軸を中心に鏡映
      positiveTri.addChild(rightTri);
    }
    positiveTri.rotate(PI * i / 3.0); // 60度回転
    tile.addChild(positiveTri); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }
}