ここでは、アイソヘドラルタイリングIH90(P6)について、解説します。
IH90(P6)
アイソヘドラルタイリングIH90(P6)の基本図形は以下のような形になります。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/IH90_P6_FundamentalbeforeTransformation.jpg)
これは、記事「基本図形の形を考える」で示したP6群の基本図形の各辺の長さを調整したもの(IH39(P6)の基本図形)を3つ組み合わせたものになっています。
IH90(P6)の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/a9a1a6140bcc4c66c9259ab80a546789.jpg)
IH90(P6)の基本図形は正三角形の形状をしています。正三角形の各頂点、および各辺の中点がそれぞれ三角格子点(黒点)と一致するようにとります。なお、正三角形を図のように点線で分けると、3つのP6群の基本図形となります。
IH90(P6)の基本図形を並べる
このIH90(P6)の基本図形をP6群の対称性を保ちながら並べると、以下のような図形が得られます。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/IH90_P6-1.jpg)
IH90(P6)の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/f2eacfed4555243aba43df374e49f200.jpg)
正三角形の3つの辺はすべて同じ辺となります。
辺\(a\)は両側のラベルが同じで異なる向きに重なっていますので、辺\(a\)は中点に対して点対称に変形します。それにより、隣り合う基本図形同士を重ねることなくP6群の対称性に従って敷き詰めることができます。
ここでは、書籍「装飾パターンの法則」のp.107にあるIH90(P6)の例を参考に、このルールに従ってIH90(P6)の基本図形を下図のように変形してみました。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/IH90_P6_FundamentalafterTransformation.jpg)
この変形した基本図形をP6群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/IH90_P6_transformation-1.jpg)
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeTriangleVector(); // 三角格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP6(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH90_P6_transformation.jpg");
}
// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = PVector.fromAngle(PI / 3);
}
// 三角格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].x); // 行の数
lattice = new PVector[col_num + 5][row_num + 1];
for (int i = 0; i < col_num + 5; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x - ((j/2) + 2) * scalar, v.y);
}
}
}
// 三角形を変形する関数(基本図形)
PShape transformTriangle(){
PVector[] v = new PVector[3]; // 三角形の頂点
v[0] = new PVector(0.0, 0.0);
v[1] = base[0].copy().mult(2.0 * scalar);
v[2] = new PVector(scalar, -base[1].y * scalar * 2.0);
// 三角形を変形する
PShape tri = createShape();
tri.beginShape();
PVector[] auxiliary_point = new PVector[5];
// 辺aを中点に対して点対称に変形する
tri.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/4.0, -1.0/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 3.0/4.0, 1.0/4.0);
tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
tri.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[1].x, v[1].y);
// 2つ目の辺aを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/4.0, -1.0/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 3.0/4.0, 1.0/4.0);
tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
tri.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[2].x, v[2].y);
// 3つ目の辺aを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[0], 1.0/4.0, -1.0/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[0], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[0], 3.0/4.0, 1.0/4.0);
tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
tri.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[0].x, v[0].y);
tri.endShape();
return tri;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP6(){
tile = createShape(GROUP); // PShapeのグループを作る
for (int i=0; i<2; i++){
PShape tri = transformTriangle(); // 変形した三角形の生成
tri.rotate(PI * i / 3); // 60度回転
tile.addChild(tri); // グループに追加
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( (i%2 == 0 && j%4 == 0) || (i%2 == 1 && j%4 == 2) ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
// 格子点を描画する
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}