IH83（CM）

ここでは、アイソヘドラルタイリングIH83（CM）について、解説します。

Contents

1 IH83（CM）
- 1.1 IH83（CM）の基本図形のサイズ
- 1.2 IH83（CM）の基本図形を並べる
2 IH83（CM）の基本図形の変形
3 プログラムコード

アイソヘドラルタイリングIH83（CM）の基本図形は以下のような形になります。

これは、記事「基本図形の形を考える」で示したCM群の基本図形の各辺の長さを調整したものになっています。なお、CM群の基本図形は五角形と台形のものがありますが、今回はどちらからスタートしても同じものが得られます。

IH83（CM）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

今回、基本図形は二等辺三角形の形状をしています。二等辺三角形の3つの頂点、および二等辺三角形の各辺の中点がそれぞれ菱形格子点（黒点）と一致するようにとります。

IH83（CM）の基本図形を並べる

このIH83（CM）の基本図形をCM群の対称性を保ちながら並べると、以下のような図形が得られます。

IH83（CM）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

辺\(a\)は両側のラベルが同じで同じ向きに重なっていますので、辺\(a\)は変形できません。辺\(b\)と辺\(c\)はお互いに同じ向きに重なっています。つまり、辺\(b\)を変形し、辺\(c\)は変形した辺\(b\)と同じ形で上下反転したものに変形します。それにより、隣り合う基本図形同士を重ねることなくCM群の対称性に従って敷き詰めることができます。

ここでは、書籍「装飾パターンの法則」のp.106にあるIH83（CM）の例を参考に、このルールに従ってIH83（CM）の基本図形を下図のように変形してみました。

この変形した基本図形をCM群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は菱形格子点も示しています。

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 10; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRhombusVector(); // 菱形格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileCM(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH83_CM_transformation.jpg");
}

// 菱形格子を張るベクトルを生成する関数
void makeRhombusVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = new PVector(0.5, 0.8);
}

// 菱形格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 2][row_num + 1];
  for (int i = 0; i < col_num + 2; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x - (j/2) * scalar, v.y);
    }
  }
}

// 三角形を変形する関数（基本図形）
PShape transformTriangle(){
  
  PVector[] v = new PVector[3]; // 三角形の頂点

  v[0] = new PVector(0.0, 0.0);
  v[1] = new PVector(2.0 * scalar, 0.0);
  v[2] = new PVector(scalar, -base[1].y * scalar * 2.0);

  // 三角形を変形する
  PShape tri = createShape();
  tri.beginShape(); 
  PVector[] auxiliary_point = new PVector[11];
  // 辺aは変形できない
  tri.vertex(v[0].x, v[0].y);
  tri.vertex(v[1].x, v[1].y);
  // 辺bを変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/4.0, -1.0/8.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 2.0/5.0, -1.0/20.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 11.0/20.0, 1.0/12.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 3.0/4.0, -1.0/16.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 7.0/8.0, -1.0/8.0);
  tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  tri.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
  tri.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, v[2].x, v[2].y);
  // 辺cは辺bと同じ形で上下反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[0], 1.0/4.0, 1.0/8.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[0], 2.0/5.0, 1.0/20.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[2], v[0], 11.0/20.0, -1.0/12.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[2], v[0], 3.0/4.0, 1.0/16.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[2], v[0], 7.0/8.0, 1.0/8.0);
  tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  tri.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
  tri.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, v[0].x, v[0].y);

  tri.endShape();
  
  return tri;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileCM(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){
    for(int j=0; j<2; j++){
      PShape tri = transformTriangle(); // 変形した三角形の生成
      tri.scale(1,pow(-1,j)); // 反転
      tri.translate(-i*scalar*base[0].x, 2.0*i*scalar*base[1].y); // 三角形の位置を調整
      tile.addChild(tri); // グループに追加
    }
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%4 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      } 
    }
  }

  // 格子点を描く
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}