IH74（CMM）

ここでは、アイソヘドラルタイリングIH74（CMM）について、解説します。

Contents

1 IH74（CMM）
- 1.1 IH74（CMM）の基本図形のサイズ
- 1.2 IH74（CMM）の基本図形を並べる
2 IH74（CMM）の基本図形の変形
3 プログラムコード

アイソヘドラルタイリングIH74（CMM）の基本図形は以下のような形になります。

これは、記事「基本図形の形を考える」で示したCMM群の基本図形の各辺の長さを調整したものを4つ組み合わせたものになっています。

IH74（CMM）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

今回、基本図形は菱形の形状をしています。菱形の4つの頂点、菱形の各辺の中点、および菱形の重心がそれぞれ菱形格子点（黒点）と一致するようにとります。なお、菱形を図のように点線で分けると、4つのCMM群の基本図形となります。

IH74（CMM）の基本図形を並べる

このIH74（CMM）の基本図形をCMM群の対称性を保ちながら並べると、以下のような図形が得られます。

IH74（CMM）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

菱形の４つの辺はすべて同じ辺となります。

辺\(a\)は両側のラベルが同じで異なる向きに重なっています。つまり、辺\(a\)は中点に対して点対称に変形することができます。それにより、隣り合う基本図形同士を重ねることなくCMM群の対称性に従って敷き詰めることができます。

ここでは、書籍「装飾パターンの法則」のp.105にあるIH74（CMM）の例を参考に、このルールに従ってIH74（CMM）の基本図形を下図のように変形してみました。

この変形した基本図形をCMM群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は菱形格子点も示しています。

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRhombusVector(); // 菱形格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileCMM(); // タイルを生成
  drawTiling(); // タイリングを描画
  
  save("IH74_CMM_transformation.jpg");
}

// 菱形格子を張るベクトルを生成する関数
void makeRhombusVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = new PVector(0.5, 0.3);
}

// 菱形格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 2][row_num + 2];
  for (int i = 0; i < col_num + 2; i++){
    for (int j = 0; j < row_num + 2; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x - (j/2) * scalar, v.y);
    }
  }
}

// 四角形を変形する関数（基本図形）
PShape transformRectangle(){
  
  PVector[] v = new PVector[4]; // 四角形の頂点
  
  v[0] = new PVector(-scalar, 0.0);
  v[1] = new PVector(0.0, 2.0 * base[1].y * scalar);
  v[2] = new PVector(scalar, 0.0);
  v[3] = new PVector(0.0, -2.0 * base[1].y * scalar);

  // 四角形を変形する
  PShape rect = createShape();
  rect.beginShape(); 
  PVector[] auxiliary_point = new PVector[23];
  // 辺aは中点に関して点対称に変形する
  rect.vertex(v[0].x, v[0].y);
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/3.0, 1.0/12.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 2.0/3.0, -1.0/12.0); 
  rect.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  rect.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
  rect.vertex(v[1].x, v[1].y);
  // 2つ目の辺aを変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/3.0, -1.0/12.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 2.0/3.0, 1.0/12.0); 
  rect.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  rect.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
  rect.vertex(v[2].x, v[2].y);
  // 3つ目の辺aを変形する 
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/3.0, 1.0/12.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 2.0/3.0, -1.0/12.0); 
  rect.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  rect.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
  rect.vertex(v[3].x, v[3].y);
  // 4つ目の辺aを変形する 
  auxiliary_point[0] = getAuxiliaryPoint(v[3], v[0], 1.0/3.0, -1.0/12.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[3], v[0], 2.0/3.0, 1.0/12.0); 
  rect.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  rect.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
  rect.vertex(v[0].x, v[0].y);

  rect.endShape();
  
  return rect;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileCMM(){
  tile = createShape(GROUP); // PShapeのグループを作る
  PShape rectangle = transformRectangle(); // 変形した四角形の生成
  tile.addChild(rectangle); // グループに追加
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( (j%4 == 0 && i%2 == 0 ) || (j%4 == 2 && i%2 == 1 ) ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      } 
    }
  }

  // 格子点を描く
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}