IH65（PMM）

  1. ホーム
  2. 壁紙アート
  3. アイソヘドラルタイリング
  4. IH65（PMM）

ここでは、アイソヘドラルタイリングIH65（PMM）について、解説します。

IH65（PMM）

アイソヘドラルタイリングIH65（PMM）の基本図形は以下のような形になります。

IH65（PMM）の基本図形

これは、記事「基本図形の形を考える」で示したPMM群の基本図形を2つ組み合わせたものになっています。

IH65（PMM）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

IH65（PMM）の基本図形のサイズ

今回、基本図形は長方形の形状をしています。この長方形の上部の２つの頂点がそれぞれ横方向に近接する長方格子点（黒点）と一致するようにとります。また、この長方形の下部の２つの頂点がそれぞれ縦方向に近接する長方格子点間の中点（赤点）と一致するようにとります。なお、長方形を図のように点線で分けると、2つのPMM群の基本図形となります。

IH65（PMM）の基本図形を並べる

このIH65（PMM）の基本図形をPMM群の対称性を保ちながら並べると、以下のような図形が得られます。

IH65（PMM）による図形

IH65（PMM）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

IH65（PMM）の基本図形に対する辺のラベルと向き

辺\(b\)と辺\(b′\)は同じ辺となります。

辺\(b\)は両側のラベルが同じで同じ向きに重なっています。つまり、辺\(b\)は変形することができません。また、辺\(a\)と辺\(c\)もそれぞれ両側のラベルが同じで同じ向きに重なっています。辺\(a\)と辺\(c\)の向きは両方の向きになっていますが、今回、辺\(a\)と辺\(c\)は変形できません。

※辺\(a\)と辺\(c\)の変形について

『辺\(a\)と辺\(c\)は変形できない』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH65（PMM）の基本図形を記事「基本図形の形を考える」で示したPMM群の基本図形に分けて考えてみます。

PMM群の基本図形に分ける

このとき、辺\(a\)は２つの辺\(a′\)、辺\(c\)は２つの辺\(c′\)にそれぞれ分けられます。辺\(a\)は辺\(a′\)を異なる向きに2つ並べたものになっていますので、辺\(a\)の変形は垂直二等分線（上図の点線）に対して線対称になります。一方、辺\(a′\)は両側のラベルが同じで同じ向きに重なっています。これは辺\(a′\)を変形できないことを示しています。つまり、辺\(a\)は変形できないことが分かります。辺\(c\)についても同様に考えると、変形できないことが分かります。

以上のことから、IH65（PMM）の基本図形は変形できないことが分かります。

IH65（PMM）の基本図形に模様をつける

IH65（PMM）の基本図形は変形できませんので、代わりに模様をつけてみます。

IH65（PMM）の基本図形は以下の図のように赤点線で示した軸に対して線対称な図形になります。

IH65（PMM）の基本図形の対称性

ここでは、この対称性を考慮して、書籍「装飾パターンの法則」のp.103にあるIH65（PMM）の例を参考に、以下のように模様を描いてみました。

IH65（PMM）の基本図形に模様を描く

この模様を描いた基本図形をPMM群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は長方格子点も示しています。

模様を描いたIH65（PMM）の基本図形による図形

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRectVector(); // 長方格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTilePMM(); // タイルを生成
  drawTiling(); // タイリングを描画
  
  save("IH65_PMM_decoration.jpg");
}

// 長方格子を張るベクトルを生成する関数
void makeRectVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 2.0);
  base[1].mult(1.2);
}

// 長方格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 1][row_num + 1];
  for (int i = 0; i < col_num + 1; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+1)*scalar), v.y);
    }
  }
}

// 四角形に模様を描く関数（基本図形）
PShape decorateRectangle(){
  
  PVector[] v = new PVector[4]; // 四角形の頂点

  v[0] = base[1].copy();
  v[0].mult(scalar / 2.0);
  v[1] = base[1].copy().mult(scalar / 2.0);
  v[1].add(base[0].copy().mult(scalar));
  v[2] = base[0].copy().mult(scalar);
  v[3] = new PVector(0.0,0.0);

  // 四角形を描く
  noFill();
  PShape rect = createShape();
  rect.beginShape(); 
  for(int i=0; i<4; i++){
    rect.vertex(v[i].x, v[i].y);
  }
  rect.endShape(CLOSE);
  
  // 模様を描く
  fill(200,0,0,128);
  PShape pattern = createShape();
  pattern.beginShape();
  PVector[] auxiliary_point = new PVector[6]; 
  auxiliary_point[0] = getAuxiliaryPoint(v[0].copy().add(v[1].copy()).mult(0.5), v[2].copy().add(v[3].copy()).mult(0.5), 2.0/15.0, 0.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[0].copy().add(v[1].copy()).mult(0.5), v[2].copy().add(v[3].copy()).mult(0.5), 3.0/5.0, 1.0/2.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[0].copy().add(v[1].copy()).mult(0.5), v[2].copy().add(v[3].copy()).mult(0.5), 4.0/5.0, 1.0/4.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[0].copy().add(v[1].copy()).mult(0.5), v[2].copy().add(v[3].copy()).mult(0.5), 3.0/5.0, 0.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[0].copy().add(v[1].copy()).mult(0.5), v[2].copy().add(v[3].copy()).mult(0.5), 4.0/5.0, -1.0/4.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[0].copy().add(v[1].copy()).mult(0.5), v[2].copy().add(v[3].copy()).mult(0.5), 3.0/5.0, -1.0/2.0);
  pattern.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  pattern.bezierVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y); 
  pattern.bezierVertex(auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[0].x, auxiliary_point[0].y); 
  pattern.endShape();
  
  PShape decoratedRect = createShape(GROUP);
  decoratedRect.addChild(rect);
  decoratedRect.addChild(pattern);

  return decoratedRect;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTilePMM(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int j=0; j<2; j++){
    PShape rectangle = decorateRectangle(); // 長方形の生成
    rectangle.scale(1,pow(-1,j)); // 長方形を反転
    tile.addChild(rectangle); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      tile.resetMatrix();
      tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
      shape(tile); // タイルを描画
    }
  }
  // 格子点を描く
  noFill();
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}