ここでは、アイソヘドラルタイリングIH47（P2）について、解説します。
IH47（P2）
アイソヘドラルタイリングIH47（P2）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したP2群の基本図形の各辺の長さを調整したものになっています。また、今回は一般格子の形状も変更しています。
IH47（P2）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
辺\(b\)と辺\(c\)の交点、および辺\(c\)と辺\(d\)の交点はそれぞれ横方向に近接する一般格子点（黒点）と一致するようにとります。また、辺\(d\)と辺\(a\)の交点、および辺\(a\)と辺\(b\)の交点はそれぞれ斜め方向に近接する一般格子点間の中点（赤点）と一致するようにとります。
IH47（P2）の基本図形を並べる
このIH47（P2）の基本図形をP2群の対称性を保ちながら並べると、以下のような図形が得られます。
IH47（P2）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
辺\(a\)と辺\(c\)がそれぞれ両側のラベルが同じで異なる向きに重なっています。つまり、辺\(a\)と辺\(c\)はそれぞれその中点に対して点対称に変形することができます。また、辺\(b\)と辺\(d\)はお互いに異なる向きに重なっています。つまり、辺\(b\)を変形し、辺\(d\)は変形した辺\(b\)と同じ形で上下左右反転した形に変形します。それにより、隣り合う基本図形同士を重ねることなくP2群の対称性に従って敷き詰めることができます。
ここでは、書籍「装飾パターンの法則」のp.101にあるIH47（P2）の例を参考に、このルールに従ってIH47（P2）の基本図形を下図のように変形してみました。
この変形した基本図形をP2群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は一般格子点も示しています。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeGeneralVector(); // 一般格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP2(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH47_P2_transformation.jpg");
}
// 一般格子を張るベクトルを生成する関数
void makeGeneralVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = PVector.fromAngle(PI * 15.0 / 24.0);
base[1].mult(1.2);
}
// 一般格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / abs(base[1].x)); // 行の数
lattice = new PVector[col_num + 3][row_num + 1];
for (int i = 0; i < col_num + 3; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0].copy(), i * scalar);
v.add(PVector.mult(base[1].copy(), j * scalar));
lattice[i][j] = v.copy(); // x軸方向にscalarの2倍だけ左にシフト
}
}
}
// 四角形を変形する関数（基本図形）
PShape transformRectangle(){
PVector[] v = new PVector[4]; // 四角形の頂点
v[0] = base[1].copy().mult(scalar / 2.0);
v[1] = base[1].copy().mult(scalar / 2.0);
v[1].add(base[0].copy().mult(scalar));
v[2] = base[0].copy().mult(scalar);
v[3] = new PVector(0.0, 0.0);
// 四角形を変形する
PShape rect = createShape();
rect.beginShape();
PVector[] auxiliary_point = new PVector[18];
// 辺aを中点に対して点対称に変形する
rect.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/10.0, -1.0/6.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/4.0, -1.0/6.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 7.0/16.0, -3.0/32.0);
auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 1.0/16.0, -1.0/32.0);
auxiliary_point[4] = getAuxiliaryPoint(v[0], v[1], 1.0/4.0, 0.0);
auxiliary_point[5] = getAuxiliaryPoint(v[0], v[1], 3.0/8.0, 0.0);
auxiliary_point[6] = getAuxiliaryPoint(v[0], v[1], 3.0/8.0, -1.0/12.0);
auxiliary_point[7] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, -1.0/12.0);
auxiliary_point[8] = getAuxiliaryPoint(v[0], v[1], 5.0/8.0, -1.0/24.0);
auxiliary_point[9] = getAuxiliaryPoint(v[0], v[1], 3.0/8.0, 1.0/24.0);
auxiliary_point[10] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, 1.0/12.0);
auxiliary_point[11] = getAuxiliaryPoint(v[0], v[1], 5.0/8.0, 1.0/12.0);
auxiliary_point[12] = getAuxiliaryPoint(v[0], v[1], 5.0/8.0, 0.0);
auxiliary_point[13] = getAuxiliaryPoint(v[0], v[1], 3.0/4.0, 0.0);
auxiliary_point[14] = getAuxiliaryPoint(v[0], v[1], 15.0/16.0, 1.0/32.0);
auxiliary_point[15] = getAuxiliaryPoint(v[0], v[1], 9.0/16.0, 3.0/32.0);
auxiliary_point[16] = getAuxiliaryPoint(v[0], v[1], 3.0/4.0, 1.0/6.0);
auxiliary_point[17] = getAuxiliaryPoint(v[0], v[1], 9.0/10.0, 1.0/6.0);
rect.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
rect.bezierVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
rect.bezierVertex(auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y, auxiliary_point[7].x, auxiliary_point[7].y);
rect.bezierVertex(auxiliary_point[8].x, auxiliary_point[8].y, auxiliary_point[9].x, auxiliary_point[9].y, auxiliary_point[10].x, auxiliary_point[10].y);
rect.bezierVertex(auxiliary_point[11].x, auxiliary_point[11].y, auxiliary_point[12].x, auxiliary_point[12].y, auxiliary_point[13].x, auxiliary_point[13].y);
rect.bezierVertex(auxiliary_point[14].x, auxiliary_point[14].y, auxiliary_point[15].x, auxiliary_point[15].y, auxiliary_point[16].x, auxiliary_point[16].y);
rect.quadraticVertex(auxiliary_point[17].x, auxiliary_point[17].y, v[1].x, v[1].y);
// 辺bを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/4.0, -1.0/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 3.0/4.0, 1.0/4.0);
auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 7.0/8.0, 0.0);
rect.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
rect.bezierVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y, v[2].x, v[2].y);
// 辺cを中点に対して点対称に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/20.0, -1.0/20.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0/20.0, -1.0/10.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 1.0/20.0, -3.0/20.0);
auxiliary_point[3] = getAuxiliaryPoint(v[2], v[3], 1.0/10.0, -1.0/10.0);
auxiliary_point[4] = getAuxiliaryPoint(v[2], v[3], 3.0/20.0, -1.0/20.0);
auxiliary_point[5] = getAuxiliaryPoint(v[2], v[3], 3.0/10.0, -3.0/40.0);
auxiliary_point[6] = getAuxiliaryPoint(v[2], v[3], 2.0/5.0, -1.0/40.0);
auxiliary_point[7] = getAuxiliaryPoint(v[2], v[3], 9.0/20.0, 0.0);
auxiliary_point[8] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, 0.0);
auxiliary_point[9] = getAuxiliaryPoint(v[2], v[3], 11.0/20.0, 0.0);
auxiliary_point[10] = getAuxiliaryPoint(v[2], v[3], 3.0/5.0, 1.0/40.0);
auxiliary_point[11] = getAuxiliaryPoint(v[2], v[3], 7.0/10.0, 3.0/40.0);
auxiliary_point[12] = getAuxiliaryPoint(v[2], v[3], 17.0/20.0, 1.0/20.0);
auxiliary_point[13] = getAuxiliaryPoint(v[2], v[3], 9.0/10.0, 1.0/10.0);
auxiliary_point[14] = getAuxiliaryPoint(v[2], v[3], 19.0/20.0, 3.0/20.0);
auxiliary_point[15] = getAuxiliaryPoint(v[2], v[3], 19.0/20.0, 1.0/10.0);
auxiliary_point[16] = getAuxiliaryPoint(v[2], v[3], 19.0/20.0, 1.0/20.0);
rect.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
rect.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
rect.bezierVertex(auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y);
rect.quadraticVertex(auxiliary_point[7].x, auxiliary_point[7].y, auxiliary_point[8].x, auxiliary_point[8].y);
rect.quadraticVertex(auxiliary_point[9].x, auxiliary_point[9].y, auxiliary_point[10].x, auxiliary_point[10].y);
rect.bezierVertex(auxiliary_point[11].x, auxiliary_point[11].y, auxiliary_point[12].x, auxiliary_point[12].y, auxiliary_point[13].x, auxiliary_point[13].y);
rect.quadraticVertex(auxiliary_point[14].x, auxiliary_point[14].y, auxiliary_point[15].x, auxiliary_point[15].y);
rect.quadraticVertex(auxiliary_point[16].x, auxiliary_point[16].y, v[3].x, v[3].y);
// 辺dを辺bと同じ形で上下左右反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[0], 1.0/8.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[3], v[0], 1.0/4.0, -1.0/4.0);
auxiliary_point[2] = getAuxiliaryPoint(v[3], v[0], 1.0/2.0, 0.0);
auxiliary_point[3] = getAuxiliaryPoint(v[3], v[0], 3.0/4.0, 1.0/4.0);
rect.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
rect.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, v[0].x, v[0].y);
rect.endShape();
return rect;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP2(){
tile = createShape(GROUP); // PShapeのグループを作る
for(int i=0; i<2; i++){
PShape hexagon = transformRectangle(); // 変形した四角形の生成
hexagon.rotate(PI * i); // 180度回転
tile.addChild(hexagon); // グループに追加
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
// 格子点を描く
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}