IH26（CMM）

  1. ホーム
  2. 壁紙アート
  3. アイソヘドラルタイリング
  4. IH26（CMM）

ここでは、アイソヘドラルタイリングIH26（CMM）について、解説します。

IH26（CMM）

アイソヘドラルタイリングIH26（CMM）の基本図形は以下のような形になります。

IH26（CMM）の基本図形

これは、記事「基本図形の形を考える」で示したCMM群の基本図形の各辺の長さを調整したものを2つ組み合わせたものになっています。

IH26（CMM）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

IH26（CMM）の基本図形のサイズ

IH26（CMM）の基本図形は五角形で、上図のように点線で2つの台形に分けると、各台形は記事「基本図形の形を考える」で示したCMM群の基本図形の各辺の長さを調整したものであり、2つの台形は点線でお互いに線対称になっています。

今回、辺\(a,c.c’\)の中点と\(a\)の端点は、近接する菱形格子点（黒点）の並びとなるように設定します。また、上図の\(r_1,r_2\)は\(r_1+r_2\)が斜め方向に近接する菱形格子点間の高さと一致するように設定します。

IH26（CMM）の基本図形を並べる

このIH26（CMM）の基本図形をCMM群の対称性を保ちながら並べると、以下のような図形が得られます。

IH26（CMM）による図形

IH26（CMM）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

IH26（CMM）の基本図形に対する辺のラベルと向き

辺\(b\)と辺\(b’\)、および辺\(c\)と辺\(c’\)はそれぞれ同じ辺となります。

辺\(a\)については今回変形できません。これは下で説明します。辺\(b\)は両側のラベルが同じで向きも同じになっています。これは、辺\(b\)が変形できないことを示しています。辺\(c\)は両側のラベルが同じで異なる向きに重なっていますので、中点に関して点対称な変形を行います。これらの変形により、隣り合う基本図形同士を重ねることなくCMM群の対称性に従って敷き詰めることができます。

※辺\(a\)の変形について

『辺\(a\)が変形できない』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH26（CMM）の基本図形を記事「基本図形の形を考える」で示したCMM群の基本図形に分けて考えてみます。

CMM群の基本図形に分ける

このとき、辺\(a\)は２つの辺\(a′\)に分けられます。辺\(a\)は辺\(a′\)を異なる向きに2つ並べたものになっていますので、辺\(a\)の変形は垂直二等分線（ここでは点線）に対して線対称になることになります。一方、辺\(a′\)の両側のラベルは同じで同じ向きに重なっています。これは辺\(a′\)が変形できないことを示しています。つまり、辺\(a\)は変形できないことが分かります。

ここでは、書籍「装飾パターンの法則」のp.98にあるIH26（CMM）の例を参考に、このルールに従ってIH26（CMM）の基本図形を下図のように変形してみました。

IH26（CMM）の基本図形の変形

この変形した基本図形をCMM群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は菱形格子点も示しています。

IH26（CMM）の変形した基本図形による図形

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRhombusVector(); // 菱形格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileCMM(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH26_CMM_transformation.jpg");
}

// 菱形格子を張るベクトルを生成する関数
void makeRhombusVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = new PVector(0.5, 1.0);
}

// 菱形格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 2][row_num + 1];
  for (int i = 0; i < col_num + 2; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x - ((j+2)/2) * scalar, v.y);
    }
  }
}

// 五角形を変形する関数（基本図形）
PShape transformPentagon(){
  
  PVector[] v = new PVector[5]; // 五角形の頂点
  float r1, r2;
  r1 = 1.0/2.0 * scalar * base[1].y;
  r2 = 1.0/2.0 * scalar * base[1].y;

  v[0] = new PVector(0.0,0.0);
  v[1] = new PVector(2.0 * scalar, 0.0);
  v[2] = new PVector(2.0 * scalar, -r1);
  v[3] = new PVector(scalar, -2.0 * r1 - r2);
  v[4] = new PVector(0.0, -r2);

  // 五角形を変形する
  PShape pentagon = createShape();
  pentagon.beginShape(); 
  PVector[] auxiliary_point = new PVector[11];
  // 辺aは変形しない
  pentagon.vertex(v[0].x, v[0].y);
  pentagon.vertex(v[1].x, v[1].y);
  // 辺bは変形しない
  pentagon.vertex(v[2].x, v[2].y);
  // 辺cは中点に対して点対称に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/4.0, -1.0/4.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 2.0/5.0, 1.0/8.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, 0.0);  
  auxiliary_point[3] = getAuxiliaryPoint(v[2], v[3], 3.0/5.0, -1.0/8.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[2], v[3], 3.0/4.0, 1.0/4.0);
  pentagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
  pentagon.bezierVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y, v[3].x, v[3].y);
  // 辺c'を辺cと同じ形に変形する（向きに注意）
  auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 1.0/4.0, 1.0/4.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[3], v[4], 2.0/5.0, -1.0/8.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[3], v[4], 1.0/2.0, 0.0);  
  auxiliary_point[3] = getAuxiliaryPoint(v[3], v[4], 3.0/5.0, 1.0/8.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[3], v[4], 3.0/4.0, -1.0/4.0);
  pentagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
  pentagon.bezierVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y, v[4].x, v[4].y);
  // 辺b'は変形しない
  pentagon.vertex(v[0].x, v[0].y);

  pentagon.endShape();
  
  return pentagon;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileCMM(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){
    PShape rectangle = transformPentagon(); // 変形した五角形の生成
    rectangle.scale(1,pow(-1,i)); // 反転
    tile.addChild(rectangle); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( (j%4 == 0 && i%2 == 0 ) || (j%4 == 2 && i%2 == 1 ) ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      } 
    }
  }

  // 格子点を描く
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}

コメントを残す