IH22（CM）

ここでは、アイソヘドラルタイリングIH22（CM）について、解説します。

Contents

1 IH22（CM）
- 1.1 IH22（CM）の基本図形のサイズ
- 1.2 IH22（CM）の基本図形を並べる
2 IH22（CM）の基本図形の変形
3 プログラムコード

アイソヘドラルタイリングIH22（CM）の基本図形は以下のような形になります。

これは、記事「基本図形の形を考える」で示したCM群の基本図形の各辺の長さを調整したものになっています。

IH22（CM）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

今回、辺\(b\)と辺\(e\)、辺\(c\)と辺\(d\)は、それぞれ同じ長さを持つように設定します。また、辺\(a\)の両端の頂点と辺\(a\)の中点はそれぞれ横方向に近接する3つの菱形格子点（黒点）と一致するようにとります。\(r_1, r_2\)は\(r_1+2r_2\)が縦方向に近接する2つの菱形格子点（黒点）間の高さの2倍と一致するように調整します。あとは、\(r_3\)の長さを適当に調整することで、この基本図形の形を決めることができます。

IH22（CM）の基本図形を並べる

このIH22（CM）の基本図形をCM群の対称性を保ちながら並べると、以下のような図形が得られます。

IH22（CM）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

辺\(a\)は両側のラベルが同じで同じ向きに重なっていますので、辺\(a\)は変形できません。辺\(b\)と辺\(e\)が異なる向きに重なっています。つまり、辺\(b\)を変形し、辺\(e\)は変形した辺\(b\)を上下左右反転した形状に変形します。辺\(c\)と辺\(d\)が同じ向きに重なっています。つまり、辺\(c\)を変形し、辺\(d\)は変形した辺\(c\)を上下反転した形状に変形します。それにより、隣り合う基本図形同士を重ねることなくCM群の対称性に従って敷き詰めることができます。

ここでは、書籍「装飾パターンの法則」のp.97にあるIH22（CM）の例を参考に、このルールに従ってIH22（CM）の基本図形を下図のように変形してみました。

この変形した基本図形をCM群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は菱形格子点も示しています。

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRhombusVector(); // 菱形格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileCM(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH22_CM_transformation.jpg");
}

// 菱形格子を張るベクトルを生成する関数
void makeRhombusVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = new PVector(0.5, 1.5);
}

// 菱形格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 2][row_num + 1];
  for (int i = 0; i < col_num + 2; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x - (j/2) * scalar, v.y);
    }
  }
}

// 五角形を変形する関数（基本図形）
PShape transformPentagon(){
  
  PVector[] v = new PVector[5]; // 五角形の頂点
  float r1, r2, r3;
  r1 = 2.0/3.0 * scalar * base[1].y;
  r2 = 2.0/3.0 * scalar * base[1].y;
  r3 = 4.0/13.0 * scalar * base[0].x;

  v[0] = new PVector(0.0, 0.0);
  v[1] = base[0].copy().mult(2.0 * scalar);
  v[2] = new PVector(-r3, -r2);
  v[2].add(base[0].copy().mult(2.0 * scalar));
  v[3] = new PVector(-base[0].x * scalar, -r1);
  v[3].add(v[2].copy());
  v[4] = new PVector(-r3, -r2);

  // 五角形を変形する
  PShape pentagon = createShape();
  pentagon.beginShape(); 
  PVector[] auxiliary_point = new PVector[11];
  // 辺aは変形しない
  pentagon.vertex(v[0].x, v[0].y);
  pentagon.vertex(v[1].x, v[1].y);
  // 辺bを変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], -r3/sqrt(pow(r3,2.0)+pow(r2,2.0)), r2/sqrt(pow(r3,2.0)+pow(r2,2.0)));
  pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[2].x, v[2].y);
  // 辺cは辺bと同じ形を上下左右反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/4.0, 1.0/4.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, 1.0/4.0);  
  auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 9.0/20.0, 0.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, -1.0/5.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[2], v[3], 3.0/4.0, 0.0);
  pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  pentagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
  pentagon.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, v[3].x, v[3].y);  
  // 辺dは辺cと同じ形を上下反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 1.0/4.0, -1.0/4.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[3], v[4], 1.0/2.0, -1.0/4.0);  
  auxiliary_point[2] = getAuxiliaryPoint(v[3], v[4], 9.0/20.0, 0.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[3], v[4], 1.0/2.0, 1.0/5.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[3], v[4], 3.0/4.0, 0.0);
  pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  pentagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
  pentagon.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, v[4].x, v[4].y);  
  // 辺eは辺bと同じ形を上下左右反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[4], v[0], 1.0 + r3/sqrt(pow(r3,2.0)+pow(r2,2.0)), -r2/sqrt(pow(r3,2.0)+pow(r2,2.0)));
  pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[0].x, v[0].y);
  
  pentagon.endShape();
  
  return pentagon;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileCM(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){
    for(int j=0; j<2; j++){
      PShape rectangle = transformPentagon(); // 変形した五角形の生成
      rectangle.scale(1,pow(-1,j)); // 反転
      rectangle.translate(-i*scalar*base[0].x, 2.0*i*scalar*base[1].y); // 五角形の位置を調整
      tile.addChild(rectangle); // グループに追加
    }
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%4 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      } 
    }
  }

  // 格子点を描く
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}