ここでは、アイソヘドラルタイリングIH1（P1）について、解説します。
IH1（P1）
アイソヘドラルタイリングIH1（P1）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したP1群の基本図形を少し傾けたものになっています。
IH1（P1）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
IH1（P1）の基本図形はそれぞれの対辺が平行で同じ長さの辺になる六角形の形状をしています。辺\(a\)、辺\(d\)のそれぞれの中点は一般格子点（黒点）と一致するようにとります。辺\(b,c,e,f\)のそれぞれの中点は近接する一般格子点間の中点（赤点）と一致するようにとります。また、上図の\(r_1,r_2\)は\(r_1+r_2\)が一般格子の縦方向の近接点同士の高さの半分になるように調整します。上図の\(r_3,r_4\)は\(r_3+r_4\)が一般格子の横方向の近接点同士距離の半分になるように調整します。
IH1（P1）の基本図形を並べる
このIH1（P1）の基本図形をP1群の対称性を保ちながら並べると、以下のような図形が得られます。
丸印は一般格子の点を表しています。
IH1（P1）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
辺\(a\)と辺\(d\)、辺\(b\)と辺\(e\)、および辺\(c\)と辺\(f\)がそれぞれ異なる向きに重なっています。つまり、辺\(a\)を変形し、辺\(d\)は、変形した辺\(a\)を上下左右反転した形状に変形します。また辺\(b\)と辺\(e\)、辺\(c\)と辺\(f\)についても同じように変形することで、隣り合う基本図形同士を重ねることなくP1群の対称性に従って敷き詰めることができます。
ここでは、書籍「装飾パターンの法則」のp.94にあるIH1（P1）の例を参考に、このルールに従ってIH1（P1）の基本図形を下図のように変形してみました。
この変形した基本図形をP1群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は一般格子点も示しています。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeGeneralVector(); // 一般格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP1(); // タイルを生成
drawTiling(); // タイリングを描画
// save("IH1_P1.jpg");
save("IH1_P1_transformation.jpg");
}
// 一般格子を張るベクトルを生成する関数
void makeGeneralVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = PVector.fromAngle(PI * 5.0 / 12.0);
base[1].mult(1.2);
}
// 一般格子を生成する関数
void makeLattice(){
int row_num;
if( abs(base[1].x) < 1.0e-6 ){
row_num = col_num;
} else {
row_num = ceil(col_num / base[1].x); // 行の数
}
lattice = new PVector[col_num + 3][row_num + 1];
for (int i = 0; i < col_num + 3; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x % ((col_num+3)*scalar) - 2.0 * scalar, v.y); // x軸方向にscalarの2倍だけ左にシフト
}
}
}
// 六角形を変形する関数（基本図形）
PShape transformHexagon(){
PVector[] v = new PVector[6]; // 六角形の頂点
float r1, r2, r3, r4;
r1 = 3.0/8.0 * scalar * base[1].y;
r2 = 1.0/8.0 * scalar * base[1].y;
r3 = 1.0/4.0 * scalar * base[0].x + 1.0/8.0 * scalar * base[1].x;
r4 = 1.0/2.0 * scalar * base[0].x - r3;
PVector[] v_temp = new PVector[6]; // 六角形の各辺の中点
v_temp[0] = base[0].copy();
v_temp[0].sub(base[1]);
v_temp[0].mult(-scalar);
v_temp[1] = base[1].copy();
v_temp[1].sub(base[0].copy().mult(0.5));
v_temp[1].mult(scalar);
v_temp[2] = base[1].copy().mult(0.5);
v_temp[2].mult(scalar);
v_temp[3] = new PVector(0.0,0.0);
v_temp[4] = base[0].copy().mult(0.5);
v_temp[4].mult(-scalar);
v_temp[5] = base[1].copy().mult(0.5);
v_temp[5].sub(base[0].copy());
v_temp[5].mult(scalar);
PVector gap;
gap = new PVector(r3,r2);
v[0] = v_temp[0].copy();
v[0].sub(gap);
v[1] = v_temp[0].copy();
v[1].add(gap);
v[2] = v[1].copy();
v[2].add((v_temp[1].copy().sub(v[1].copy())).mult(2.0));
v[3] = v[2].copy();
v[3].add((v_temp[2].copy().sub(v[2].copy())).mult(2.0));
v[4] = v[3].copy();
v[4].add((v_temp[3].copy().sub(v[3].copy())).mult(2.0));
v[5] = v[4].copy();
v[5].add((v_temp[4].copy().sub(v[4].copy())).mult(2.0));
// 六角形を変形する
PShape hexagon = createShape();
hexagon.beginShape();
PVector[] auxiliary_point = new PVector[2];
// 辺aを変形する
hexagon.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, -1.0/2.0);
hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[1].x, v[1].y);
// 辺bを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/3.0, -1.0/2.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 2.0/3.0, 0.0);
hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[2].x, v[2].y);
// 辺cを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/3.0, -2.0/3.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 7.0/8.0, 1.0/4.0);
hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[3].x, v[3].y);
// 辺dを辺aと同じ形を上下左右反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 1.0/2.0, 1.0/2.0);
hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[4].x, v[4].y);
// 辺eを辺bと同じ形を上下左右反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[4], v[5], 1.0/3.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[4], v[5], 2.0/3.0, 1.0/2.0);
hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[5].x, v[5].y);
// 辺fを辺cと同じ形を上下左右反転した形に変形する変形する
auxiliary_point[0] = getAuxiliaryPoint(v[5], v[0], 1.0/8.0, -1.0/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[5], v[0], 2.0/3.0, 2.0/3.0);
hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[0].x, v[0].y);
hexagon.endShape();
return hexagon;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP1(){
tile = createShape(GROUP); // PShapeのグループを作る
PShape hexagon = transformHexagon(); // 変形後の基本図形の生成
tile.addChild(hexagon); // グループに追加
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
// 格子点を描く
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}