ここでは、アイソヘドラルタイリングIH19(P3M1)について、解説します。
Contents
IH19(P3M1)
アイソヘドラルタイリングIH19(P3M1)の基本図形は以下のような形になります。
![](https://www.mathartroom.com/wp-content/uploads/2022/09/IH19_P3M1_FundamentalbeforeTransformation.jpg)
これは、記事「基本図形の形を考える」で示したP3M1群の基本図形を6つ組み合わせたものになっています。
IH19(P3M1)の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
![](https://www.mathartroom.com/wp-content/uploads/2022/09/21420f9a5c07e7bc8ae364aabe4b8aac.jpg)
IH19(P3M1)の基本図形は正六角形で、上図のように点線で6つの正三角形に分けると、各正三角形は記事「基本図形の形を考える」で示したP3M1群の基本図形になっています。
今回、正六角形の各頂点はそのうち3つが近接する三角格子点(黒点)の並びとなり、残りの3つが近接する三角格子の重心位置(赤点)になるように設定します。その結果、正六角形の一辺の長さ\(r_1\)は、近接する三角格子点間の距離の\(1/\sqrt{3}\)になります。
IH19(P3M1)の基本図形を並べる
このIH19(P3M1)の基本図形をP3M1群の対称性を保ちながら並べると、以下のような図形が得られます。
![](https://www.mathartroom.com/wp-content/uploads/2022/09/IH19_P3M1.jpg)
IH19(P3M1)の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/6343c241a24d35f87594c387c02e3c0f.jpg)
今回、正六角形の各辺は同じ辺となります。
辺\(a\)は両側のラベルが同じで向きも同じになっています。これは、辺\(a\)が変形できないことを示しています。つまり、IH19(P3M1)の基本図形は変形することができないことになります。
IH19(P3M1)の基本図形に模様をつける
IH19(P3M1)の基本図形は変形できませんので、代わりに模様をつけてみます。
IH19(P3M1)の基本図形は以下の図のように赤点線で示した軸に対して線対称であり、また正六角形の重心(赤三角点)を中心とした120°回転について対称な図形になります。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/IH19_P3M1_transformation.jpg)
ここでは、この対称性を考慮して、書籍「装飾パターンの法則」のp.97にあるIH19(P3M1)の例を参考に、以下のように模様を描いてみました。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/IH19_P3M1_decorationForFundamental.jpg)
この模様を描いた基本図形をP3M1群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/IH19_P3M1_decoration.jpg)
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000,1000,P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと列の数からタイルの大きさを決定
makeTriangleVector(); // 三角格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP3M1(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH19_P3M1_decoration.jpg");
}
// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
base[0] = PVector.fromAngle(0.0);
base[1] = PVector.fromAngle(PI / 3);
}
// 三角格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].x); // 行の数
lattice = new PVector[col_num + 3][row_num];
for (int i = 0; i < col_num + 3; i++){
for (int j = 0; j < row_num; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x - ((j/2) + 2) * scalar, v.y);
}
}
}
// 六角形に模様を描く関数(基本図形)
PShape decorateHexagon(){
PVector[] v = new PVector[6]; // 六角形の頂点
PVector center = PVector.fromAngle(-radians(30)); // 六角形の重心位置
center.mult(1.0 / sqrt(3.0) * scalar);
for(int i=0; i<6; i++){
v[i] = PVector.fromAngle(radians(150)-i*radians(60));
v[i].mult(1.0 / sqrt(3.0) * scalar);
v[i].add(center);
}
// 六角形を描く
PShape hexagon = createShape();
hexagon.beginShape();
for(int i=0; i<6; i++){
hexagon.vertex(v[i].x, v[i].y);
}
hexagon.endShape(CLOSE);
// 模様を描く
fill(200,0,0,128);
PShape pattern = createShape();
pattern.beginShape();
PVector[] auxiliary_point = new PVector[12];
auxiliary_point[0] = getAuxiliaryPoint(v[0], center, 1.0/2.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], center, 0.0, 1.0/2.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0].copy().add(v[2].copy()).mult(0.5), center, 3.0/4.0, 0.0);
auxiliary_point[3] = getAuxiliaryPoint(v[2], center, 0.0, -1.0/2.0);
auxiliary_point[4] = getAuxiliaryPoint(v[2], center, 1.0/2.0, 0.0);
auxiliary_point[5] = getAuxiliaryPoint(v[2], center, 0.0, 1.0/2.0);
auxiliary_point[6] = getAuxiliaryPoint(v[2].copy().add(v[4].copy()).mult(0.5), center, 3.0/4.0, 0.0);
auxiliary_point[7] = getAuxiliaryPoint(v[4], center, 0.0, -1.0/2.0);
auxiliary_point[8] = getAuxiliaryPoint(v[4], center, 1.0/2.0, 0.0);
auxiliary_point[9] = getAuxiliaryPoint(v[4], center, 0.0, 1.0/2.0);
auxiliary_point[10] = getAuxiliaryPoint(v[4].copy().add(v[0].copy()).mult(0.5), center, 3.0/4.0, 0.0);
auxiliary_point[11] = getAuxiliaryPoint(v[0], center, 0.0, -1.0/2.0);
pattern.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
pattern.quadraticVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
pattern.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
pattern.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y);
pattern.quadraticVertex(auxiliary_point[7].x, auxiliary_point[7].y, auxiliary_point[8].x, auxiliary_point[8].y);
pattern.quadraticVertex(auxiliary_point[9].x, auxiliary_point[9].y, auxiliary_point[10].x, auxiliary_point[10].y);
pattern.quadraticVertex(auxiliary_point[11].x, auxiliary_point[11].y, auxiliary_point[0].x, auxiliary_point[0].y);
pattern.endShape();
PShape decoratedHexagon = createShape(GROUP);
decoratedHexagon.addChild(hexagon);
decoratedHexagon.addChild(pattern);
return decoratedHexagon;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP3M1(){
tile = createShape(GROUP); // PShapeのグループを作る
PShape hexagon = decorateHexagon(); // 正六角形の生成
tile.addChild(hexagon); // グループに追加
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (PVector[] vecArr: lattice){
for (PVector vec : vecArr){
tile.resetMatrix();
tile.translate(vec.x, vec.y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
// 格子点を描く
noFill();
for (PVector[] vecArr: lattice){
for (PVector vec : vecArr){
circle(vec.x, vec.y,10);
}
}
}