ここでは、アイソヘドラルタイリングIH14（CM）について、解説します。
IH14（CM）
アイソヘドラルタイリングIH14（CM）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したCM群の基本図形（台形）の各辺の長さを調整したものを2つ組み合わせたものになっています。また、今回は菱形格子の縦横比も調整しています。
IH14（CM）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
IH14（CM）の基本図形は六角形で、上図のように点線で2つの台形に分けると、各台形は記事「基本図形の形を考える」で示したCM群の基本図形（台形）の各辺の長さを調整したものであり、2つの台形は点線でお互いに線対称になっています。
今回、各辺の中点と六角形の重心は、近接する菱形格子点（黒点）の並びとなるように設定します。また、上図の\(r_1, r_2\)は\(r_1+r_2\)が横方向に近接する菱形格子点の幅の半分となるように設定します。
IH14（CM）の基本図形を並べる
このIH14（CM）の基本図形をCM群の対称性を保ちながら並べると、以下のような図形が得られます。
IH14（CM）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
辺\(a\)と辺\(a’\)、辺\(b\)と辺\(b’\)、辺\(c\)と辺\(c’\)はそれぞれ同じ辺となります。
辺\(a\)と辺\(c\)が同じ向きに重なっています。辺\(a\)を変形し、辺\(c\)は変形した辺\(a\)を上下反転した形状に変形します。辺\(b\)は同じラベルが同じ向きで重なっています。これは、辺\(b\)が変形できないことを示しています。これらの変形により、隣り合う基本図形同士を重ねることなくCM群の対称性に従って敷き詰めることができます。
ここでは、書籍「装飾パターンの法則」のp.96にあるIH14（CM）の例を参考に、このルールに従ってIH14（CM）の基本図形を下図のように変形してみました。
この変形した基本図形をCM群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は菱形格子点も示しています。
ちなみに、書籍「装飾パターンの法則」のp.96にあるIH14（CM）の例（一番右の図）は間違っているようです。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeRhombusVector(); // 菱形格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileCM(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH14_CM_transformation.jpg");
}
// 菱形格子を張るベクトルを生成する関数
void makeRhombusVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = new PVector(0.5, 0.3);
}
// 菱形格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].y); // 行の数
lattice = new PVector[col_num + 2][row_num + 1];
for (int i = 0; i < col_num + 2; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x - (j/2) * scalar, v.y);
}
}
}
// 六角形を変形する関数（基本図形）
PShape transformHexagon(){
PVector[] v = new PVector[6]; // 六角形の頂点
float r1, r2;
r1 = 7.0/11.0 * base[0].x * scalar / 2.0;
r2 = 4.0/11.0 * base[0].x * scalar / 2.0;
v[0] = new PVector(-r1, - base[1].y * scalar);
v[1] = new PVector(r1, base[1].y * scalar);
v[2] = new PVector(r2, 0.0);
v[2].add(base[1].copy().mult(scalar));
v[3] = new PVector(r1, - base[1].y * scalar);
v[3].add(base[0].copy().mult(scalar));
v[4] = new PVector(r2, 0.0);
v[4].add(base[0].copy().mult(2.0 * scalar));
v[4].sub(base[1].copy().mult(3.0 * scalar));
v[5] = new PVector(-r2, 0.0);
v[5].add(base[0].copy().mult(2.0 * scalar));
v[5].sub(base[1].copy().mult(3.0 * scalar));
// 六角形を変形する
PShape hexagon = createShape();
hexagon.beginShape();
PVector[] auxiliary_point = new PVector[5];
// 辺aを変形する
hexagon.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/20.0, 1.0/20.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/5.0, -1.0/8.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 2.0/5.0, -1.0/4.0);
auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, 1.0/40.0);
auxiliary_point[4] = getAuxiliaryPoint(v[0], v[1], 3.0/4.0, -1.0/20.0);
hexagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.quadraticVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.vertex(auxiliary_point[3].x, auxiliary_point[3].y);
hexagon.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, v[1].x, v[1].y);
// 辺bは変形しない
hexagon.vertex(v[2].x, v[2].y);
// 辺cを辺aと同じ形を上下反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/20.0, -1.0/20.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0/5.0, 1.0/8.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 2.0/5.0, 1.0/4.0);
auxiliary_point[3] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, -1.0/40.0);
auxiliary_point[4] = getAuxiliaryPoint(v[2], v[3], 3.0/4.0, 1.0/20.0);
hexagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.quadraticVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.vertex(auxiliary_point[3].x, auxiliary_point[3].y);
hexagon.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, v[3].x, v[3].y);
// 辺c'を辺cと同じ形に変形する（向きに注意）
auxiliary_point[0] = getAuxiliaryPoint(v[4], v[3], 1.0/20.0, 1.0/20.0);
auxiliary_point[1] = getAuxiliaryPoint(v[4], v[3], 1.0/5.0, -1.0/8.0);
auxiliary_point[2] = getAuxiliaryPoint(v[4], v[3], 2.0/5.0, -1.0/4.0);
auxiliary_point[3] = getAuxiliaryPoint(v[4], v[3], 1.0/2.0, 1.0/40.0);
auxiliary_point[4] = getAuxiliaryPoint(v[4], v[3], 3.0/4.0, -1.0/20.0);
hexagon.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[3].x, auxiliary_point[3].y);
hexagon.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.quadraticVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.vertex(v[4].x, v[4].y);
// 辺b'は変形しない
hexagon.vertex(v[5].x, v[5].y);
// 辺a'を辺aと同じ形に変形する（向きに注意）
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[5], 1.0/20.0, -1.0/20.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[5], 1.0/5.0, 1.0/8.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[5], 2.0/5.0, 1.0/4.0);
auxiliary_point[3] = getAuxiliaryPoint(v[0], v[5], 1.0/2.0, -1.0/40.0);
auxiliary_point[4] = getAuxiliaryPoint(v[0], v[5], 3.0/4.0, 1.0/20.0);
hexagon.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[3].x, auxiliary_point[3].y);
hexagon.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.quadraticVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.vertex(v[0].x, v[0].y);
hexagon.endShape();
return hexagon;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileCM(){
tile = createShape(GROUP); // PShapeのグループを作る
for(int i=0; i<2; i++){
PShape rectangle = transformHexagon(); // 変形した六角形の生成
rectangle.translate(i*scalar*base[0].x, 2.0*i*scalar*base[1].y); // 六角形の位置を調整
tile.addChild(rectangle); // グループに追加
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( i%2 == 0 && j%4 == 0 ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
// 格子点を描く
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}