ここでは、書籍「M.C.エッシャーと楽しむ算数・数学パズル」のp.48-53に紹介されている「オシドリの模様その２」をProcessingで簡略化した形で再現してみましたので、その描き方とともに紹介したいと思います。
オシドリの模様
今回描いてみたオシドリの模様は以下のような図形になりました。
描き方
このオシドリの模様は壁紙群PGGに分類されるものになります。オシドリの模様の基本図形は以下のような形状をしています。
この基本図形を準備することができれば、後はPGG群のルールに従って基本図形を並べていくことでオシドリの模様を描くことができます。
PGG群の基本図形を選ぶ
オシドリの模様の基本図形は、PGG群の基本図形を変形して作成します。そのためにまずPGG群の基本図形を選ぶ必要があります。以前紹介した記事「基本図形の形を考える」の「PGG群の基本図形の形状」の節を参考にして、今回は長方形の形状を選びます。
PGG群の基本図形の変形
PGG群の基本図形を変形するために、隣り合う基本図形同士の辺のラベルと向きをみてみます。
辺\(a\)と辺\(c\)、および辺\(b\)と辺\(d\)はそれぞれ同じ向きに重なっています。つまり、辺\(a\)を適当に変形したあと、辺\(c\)は、変形した辺\(a\)を上下反転した形状に変形します。辺\(b\)と辺\(d\)にも同様の変形を行います。そうすると、隣り合う基本図形同士を重ねることなくPGG群の対称性に従って敷き詰めることができます。
辺\(a\)と辺\(c\)の変形
辺\(a\)と辺\(c\)の変形についてみていきます。まず辺\(a\)を下図のようにおきます（薄い線）。辺\(a\)の始点を原点\((0,0)\)として、辺\(a\)と平行に\(x\)軸（左向きを正）、辺\(a\)と垂直下向きに\(y\)軸をとります。辺\(a\)の長さを\(1\)とすると、辺\(a\)の終点の座標は\((1,0)\)となります。今回、辺\(a\)の変形を下図の黒線のように3点を経由した折れ線にとります。
また、辺\(c\)の変形は辺\(a\)で変形したものを辺\(c\)の部分に上下反転させて置くことで実現できます。
辺\(b\)と辺\(d\)の変形
次に、辺\(b\)と辺\(d\)の変形についてみていきます。上記の辺\(a\)と同様に、辺\(b\)に対して座標軸を設定して、辺\(b\)の変形を下図の黒線のように3点を経由した折れ線にとります。
また、辺\(d\)の変形は辺\(b\)で変形したものを辺\(d\)の部分に上下反転させて置くことで実現できます。
これらを実施した結果、PGG群の基本図形はオシドリの模様の基本図形に変形することができます。
オシドリの模様を完成させる
PGG群の基本図形を変形した基本図形をPGG群の対称性を考慮して並べていくと、最初に示したような図形を得ることができます。
プログラムコード
最後に、プログラムコードを載せておきます。基本は別記事「渦巻き図形（PGG）」に記載しているプログラムコードのうち、makeRecurRectangle関数をtransformIsoscelesRectangle関数に書き換え、makeTilePGG関数を図形の配色に注意して書き換えたものになります。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeRectVector(); // 長方格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTilePGG(); // タイルを生成
drawTiling(); // タイリングを描画
save("PGG_mandarin_duck.jpg");
}
// 長方格子を張るベクトルを生成する関数
void makeRectVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = PVector.fromAngle(PI / 2.0);
base[1].mult(1.2);
}
// 長方格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].y); // 行の数
lattice = new PVector[col_num + 1][row_num + 1];
for (int i = 0; i < col_num + 1; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x % ((col_num+1)*scalar), v.y);
}
}
}
// 長方形を変形する関数（基本図形）
PShape transformRectangle(){
PVector[] v = new PVector[4]; // 長方形の頂点
PShape rect = createShape();
v[0] = base[0].copy();
v[0].sub(base[1]);
v[0].mult(-scalar / 2.0);
v[1] = base[0].copy();
v[1].add(base[1]);
v[1].mult(scalar / 2.0);
v[2] = base[0].copy();
v[2].sub(base[1]);
v[2].mult(scalar / 2.0);
v[3] = base[0].copy();
v[3].add(base[1]);
v[3].mult(-scalar / 2.0);
// 長方形を変形する
rect.beginShape();
PVector[] auxiliary_point = new PVector[3];
// 辺aを変形する
rect.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/5.0, -1.0/16.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 3.0/7.0, 1.0/8.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 3.0/5.0, -1.0/4.0);
rect.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
rect.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
rect.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
rect.vertex(v[1].x, v[1].y);
// 辺bを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 2.0/5.0, 1.0/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 4.0/7.0, -1.0/16.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 4.0/5.0, 1.0/32.0);
rect.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
rect.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
rect.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
rect.vertex(v[2].x, v[2].y);
// 辺cを辺aを上下に反転させた形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/5.0, 1.0/16.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 3.0/7.0, -1.0/8.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 3.0/5.0, 1.0/4.0);
rect.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
rect.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
rect.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
rect.vertex(v[3].x, v[3].y);
// 辺dを辺bを上下に反転させた形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[0], 2.0/5.0, -1.0/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[3], v[0], 4.0/7.0, 1.0/16.0);
auxiliary_point[2] = getAuxiliaryPoint(v[3], v[0], 4.0/5.0, -1.0/32.0);
rect.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
rect.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
rect.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
rect.vertex(v[0].x, v[0].y);
rect.endShape();
return rect;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTilePGG(){
tile = createShape(GROUP); // PShapeのグループを作る
for(int i=0; i<2; i++){
for(int j=0; j<2; j++){
noStroke();
if( (i % 2 == 0 && j == 0 )
|| (i % 2 == 1 && j == 1 )
){
fill(0,0,0);
} else {
fill(255,255,255);
}
PShape rectangle = transformRectangle(); // 再帰的な長方形の生成
rectangle.scale(pow(-1,i),pow(-1,j)); // 長方形の反転
rectangle.translate((0.5-j)*scalar, (0.5-i)*scalar*base[1].y); // 長方形の位置を調整
tile.addChild(rectangle); // グループに追加
}
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( i%2 == 0 && j%2 == 0 ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
}