ここでは、アイソヘドラルタイリングIH91（CMM）について、解説します。
Contents
IH91（CMM）
アイソヘドラルタイリングIH91（CMM）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したCMM群の基本図形の各辺の長さを調整したものを2つ組み合わせたものになっています。
IH91（CMM）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
今回、基本図形は二等辺三角形の形状をしています。この二等辺三角形の各頂点、および二等辺三角形の各辺の中点がそれぞれ近接する菱形格子点（黒点）と一致するようにとります。なお、台形を図のように点線で分けると、2つのCMM群の基本図形となります。
IH91（CMM）の基本図形を並べる
このIH91（CMM）の基本図形をCMM群の対称性を保ちながら並べると、以下のような図形が得られます。
IH91（CMM）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
辺\(b\)と辺\(b′\)は同じ辺となります。
辺\(a\)は両方の向きに取っています。今回、辺\(a\)は変形できません。辺\(b\)は両側のラベルが同じで異なる向きに重なっています。つまり、辺\(b\)はその中点に対して点対称に変形することができます。それにより、隣り合う基本図形同士を重ねることなくCMM群の対称性に従って敷き詰めることができます。
※辺\(a\)の変形について
『辺\(a\)は変形できない』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH91（CMM）の基本図形を記事「基本図形の形を考える」で示したCMM群の基本図形に分けて考えてみます。
このとき、辺\(a\)は２つの辺\(a′\)に分けられます。辺\(a\)は辺\(a’\)を異なる向きに2つ並べたものになっていますので、辺\(a\)の変形は垂直二等分線（上図の点線）に対して線対称になります。一方、辺\(a’\)は両側のラベルが同じで同じ向きに重なっています。これは辺\(a’\)を変形できないことを示しています。つまり、辺\(a\)は変形できないことが分かります。
ここでは、書籍「装飾パターンの法則」のp.107にあるIH91（CMM）の例を参考に、このルールに従ってIH91（CMM）の基本図形を下図のように変形してみました。
この変形した基本図形をCMM群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は菱形格子点も示しています。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeRhombusVector(); // 菱形格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileCMM(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH91_CMM_transformation.jpg");
}
// 菱形格子を張るベクトルを生成する関数
void makeRhombusVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = new PVector(0.5, 0.6);
}
// 菱形格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].y); // 行の数
lattice = new PVector[col_num + 2][row_num + 2];
for (int i = 0; i < col_num + 2; i++){
for (int j = 0; j < row_num + 2; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x - (j/2) * scalar, v.y);
}
}
}
// 三角形を変形する関数（基本図形）
PShape transformTriangle(){
PVector[] v = new PVector[4]; // 三角形の頂点
v[0] = new PVector(-scalar, 0.0);
v[1] = new PVector(scalar, 0.0);
v[2] = new PVector(0.0, -2.0 * base[1].y * scalar);
// 三角形を変形する
PShape tri = createShape();
tri.beginShape();
PVector[] auxiliary_point = new PVector[23];
// 辺aは変形できない
tri.vertex(v[0].x, v[0].y);
tri.vertex(v[1].x, v[1].y);
// 辺bを中点に関して点対称に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/8.0, 1.0/12.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/4.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 3.0/8.0, -1.0/6.0);
auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, 0.0);
auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 5.0/8.0, 1.0/6.0);
auxiliary_point[5] = getAuxiliaryPoint(v[1], v[2], 3.0/4.0, 0.0);
auxiliary_point[6] = getAuxiliaryPoint(v[1], v[2], 7.0/8.0, -1.0/12.0);
tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
tri.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
tri.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[5].x, auxiliary_point[5].y);
tri.quadraticVertex(auxiliary_point[6].x, auxiliary_point[6].y, v[2].x, v[2].y);
// 辺b'を辺bと同じ形に変形する（向きに注意）
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[0], 1.0/8.0, -1.0/12.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[0], 1.0/4.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[0], 3.0/8.0, 1.0/6.0);
auxiliary_point[3] = getAuxiliaryPoint(v[2], v[0], 1.0/2.0, 0.0);
auxiliary_point[4] = getAuxiliaryPoint(v[2], v[0], 5.0/8.0, -1.0/6.0);
auxiliary_point[5] = getAuxiliaryPoint(v[2], v[0], 3.0/4.0, 0.0);
auxiliary_point[6] = getAuxiliaryPoint(v[2], v[0], 7.0/8.0, 1.0/12.0);
tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
tri.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
tri.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[5].x, auxiliary_point[5].y);
tri.quadraticVertex(auxiliary_point[6].x, auxiliary_point[6].y, v[0].x, v[0].y);
tri.endShape();
return tri;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileCMM(){
tile = createShape(GROUP); // PShapeのグループを作る
for(int i=0; i<2; i++){
PShape rectangle = transformTriangle(); // 変形した三角形の生成
rectangle.scale(1, pow(-1,i)); // 三角形の反転
tile.addChild(rectangle); // グループに追加
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( (j%4 == 0 && i%2 == 0 ) || (j%4 == 2 && i%2 == 1 ) ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
// 格子点を描く
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}