ここでは、アイソヘドラルタイリングIH87(P3M1)について、解説します。
Contents
IH87(P3M1)
アイソヘドラルタイリングIH87(P3M1)の基本図形は以下のような形になります。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/IH87_P3M1_FundamentalbeforeTransformation.jpg)
これは、記事「基本図形の形を考える」で示したP3M1群の基本図形になっています。
IH87(P3M1)の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/23b33055025392d7dac8bd1a94198d34.jpg)
IH87(P3M1)の基本図形は正三角形の形状をしています。辺\(a\)と辺\(c\)の交点は三角格子点(黒点)と一致するようにとり、辺\(a\)と辺\(b\)の交点、および辺\(b\)と辺\(c\)の交点はそれぞれ近接する三角格子点の重心(赤点)と一致するようにとります。
IH87(P3M1)の基本図形を並べる
このIH87(P3M1)の基本図形をP3M1群の対称性を保ちながら並べると、以下のような図形が得られます。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/IH87_P3M1_transformation.jpg)
IH87(P3M1)の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/618faf4b94fca97aa674ea092329db45.jpg)
辺\(a,b,c\)は3辺ともに両側のラベルが同じで向きも同じになっています。これは、辺\(a,b,c\)のすべてが変形できないことを示しています。つまり、IH87(P3M1)の基本図形は変形することができないことになります。
IH87(P3M1)の基本図形に模様をつける
IH87(P3M1)の基本図形は変形できませんので、代わりに模様をつけてみます。
IH87(P3M1)の基本図形自身には特に対称性がありませんので、模様は自由に描くことができますが、他のアイソヘドラルタイリング(IH89(P31M)やIH93(P6M))と区別するために非対称な形の模様を描きます。
ここでは、書籍「装飾パターンの法則」のp.106にあるIH87(P3M1)の例を参考に、以下のように模様を描いてみました。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/IH87_P3M1_decorationForFundamental.jpg)
この模様を描いた基本図形をP3M1群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。
![](https://www.mathartroom.com/wp-content/uploads/2022/11/IH87_P3M1_decoration-1.jpg)
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000,1000,P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと列の数からタイルの大きさを決定
makeTriangleVector(); // 三角格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP3M1(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH87_P3M1_decoration.jpg");
}
// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
base[0] = PVector.fromAngle(0.0);
base[1] = PVector.fromAngle(PI / 3);
}
// 三角格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].x); // 行の数
lattice = new PVector[col_num + 3][row_num + 1];
for (int i = 0; i < col_num + 3; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x % ((col_num+3)*scalar) - 2 * scalar, v.y); // x軸方向にscalarの2倍だけ左にシフト
}
}
}
// 三角形に模様を描く関数(基本図形)
PShape decorateTriangle(){
PVector[] v = new PVector[3]; // 三角形の頂点
v[0] = new PVector(0,0);
v[1] = PVector.fromAngle(PI / 6);
v[1].mult(scalar / sqrt(3));
v[2] = PVector.fromAngle(-PI / 6);
v[2].mult(scalar / sqrt(3));
// 三角形を描く
// fill(255,255,255);
noFill();
PShape tri = createShape();
tri.beginShape(TRIANGLES); // 3点ずつの頂点から直角三角形を作る
for (int i=0; i<3; i++){
tri.vertex(v[i].x, v[i].y);
}
tri.endShape();
// 模様を描く
fill(200,0,0,128);
// PVector center = new PVector((v[1].x+v[2].x)/2.0, (v[1].y+v[2].y)/2.0);
PShape pattern = createShape();
pattern.beginShape();
PVector[] auxiliary_point = new PVector[4];
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/4.0, -1.0/10.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 5.0/8.0, -3.0/5.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 3.0/4.0, -7.0/20.0);
auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 5.0/8.0, -1.0/10.0);
pattern.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
pattern.bezierVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
pattern.endShape(CLOSE);
PShape decoratedTri = createShape(GROUP);
decoratedTri.addChild(tri);
decoratedTri.addChild(pattern);
return decoratedTri;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP3M1(){
tile = createShape(GROUP); // PShapeのグループを作る
for (int i=0; i<2; i++){
for (int j=0; j<3; j++){
PShape tri = decorateTriangle(); // 正三角形の生成
tri.rotate(2 * PI * j / 3); // 120度回転
tri.scale(pow(-1, i), 1); // y軸を中心に鏡映
tile.addChild(tri); // グループに追加
}
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (PVector[] vecArr: lattice){
for (PVector vec : vecArr){
tile.resetMatrix();
tile.translate(vec.x, vec.y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
// 格子点を描く
noFill();
for (PVector[] vecArr: lattice){
for (PVector vec : vecArr){
circle(vec.x, vec.y,10);
}
}
}