IH84（P2）

  1. ホーム
  2. 壁紙アート
  3. アイソヘドラルタイリング
  4. IH84（P2）

ここでは、アイソヘドラルタイリングIH84（P2）について、解説します。

IH84（P2）

アイソヘドラルタイリングIH84（P2）の基本図形は以下のような形になります。

IH84（P2）の基本図形

これは、記事「基本図形の形を考える」で示したP2群の基本図形の各辺の長さを調整したものになっています。

IH84（P2）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

IH84（P2）の基本図形のサイズ

今回、基本図形は三角形にとります。三角形の各頂点はそれぞれ近接する一般格子点（黒点）と一致するようにとります。

IH84（P2）の基本図形を並べる

このIH84（P2）の基本図形をP2群の対称性を保ちながら並べると、以下のような図形が得られます。

IH84（P2）による図形

IH84（P2）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

IH84（P2）の基本図形に対する辺のラベルと向き

辺\(a,b,c\)はそれぞれ両側のラベルが同じで異なる向きに重なっています。つまり、辺\(a,b,c\)はすべて中点に対して点対称に変形することができます。それにより、隣り合う基本図形同士を重ねることなくP2群の対称性に従って敷き詰めることができます。

ここでは、書籍「装飾パターンの法則」のp.106にあるIH84（P2）の例を参考に、このルールに従ってIH84（P2）の基本図形を下図のように変形してみました。

IH84（P2）の基本図形の変形

この変形した基本図形をP2群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は一般格子点も示しています。

IH84（P2）の変形した基本図形による図形

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeGeneralVector(); // 一般格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP2(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH84_P2_transformation.jpg");
}

// 一般格子を張るベクトルを生成する関数
void makeGeneralVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI * 15.0 / 24.0);
  base[1].mult(0.8);
}

// 一般格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / abs(base[1].x)); // 行の数
  lattice = new PVector[col_num + 3][row_num + 1];
  for (int i = 0; i < col_num + 3; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0].copy(), i * scalar); 
      v.add(PVector.mult(base[1].copy(), j * scalar));
      lattice[i][j] = v.copy(); 
    }
  }
}

// 三角形を変形する関数（基本図形）
PShape transformTriangle(){
  
  PVector[] v = new PVector[4]; // 三角形の頂点
  
  v[0] = new PVector(0.0, 0.0);
  v[1] = base[0].copy().mult(scalar);
  v[2] = base[1].copy().mult(-scalar);

  // 三角形を変形する
  PShape tri = createShape();
  tri.beginShape(); 
  PVector[] auxiliary_point = new PVector[11];
  // 辺aを中点に対して点対称に変形する
  tri.vertex(v[0].x, v[0].y);
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/8.0, 1.0/8.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/4.0, 0.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 3.0/8.0, -1.0/8.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 7.0/16.0, -3.0/16.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[0], v[1], 9.0/16.0, -1.0/16.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, 0.0);
  auxiliary_point[6] = getAuxiliaryPoint(v[0], v[1], 7.0/16.0, 1.0/16.0);
  auxiliary_point[7] = getAuxiliaryPoint(v[0], v[1], 9.0/16.0, 3.0/16.0);
  auxiliary_point[8] = getAuxiliaryPoint(v[0], v[1], 5.0/8.0, 1.0/8.0);
  auxiliary_point[9] = getAuxiliaryPoint(v[0], v[1], 3.0/4.0, 0.0);  
  auxiliary_point[10] = getAuxiliaryPoint(v[0], v[1], 7.0/8.0, -1.0/8.0);
  tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  tri.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
  tri.bezierVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[5].x, auxiliary_point[5].y);
  tri.bezierVertex(auxiliary_point[6].x, auxiliary_point[6].y, auxiliary_point[7].x, auxiliary_point[7].y, auxiliary_point[8].x, auxiliary_point[8].y);
  tri.vertex(auxiliary_point[9].x, auxiliary_point[9].y);
  tri.quadraticVertex(auxiliary_point[10].x, auxiliary_point[10].y, v[1].x, v[1].y);
  // 辺bを中点に対して点対称に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/8.0, 1.0/6.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 3.0/16.0, -1.0/20.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, 0.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 13.0/16.0, 1.0/20.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 7.0/8.0, -1.0/6.0);
  tri.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
  tri.bezierVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y, v[2].x, v[2].y);
  // 辺cを中点に対して点対称に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[0], 0.0, 1.0/30.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[0], 1.0/8.0, 1.0/30.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[2], v[0], 1.0/4.0, 1.0/3.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[2], v[0], 7.0/16.0, 1.0/30.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[2], v[0], 7.0/16.0, 0.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[2], v[0], 9.0/16.0, 0.0);
  auxiliary_point[6] = getAuxiliaryPoint(v[2], v[0], 9.0/16.0, -1.0/30.0);
  auxiliary_point[7] = getAuxiliaryPoint(v[2], v[0], 3.0/4.0, -1.0/3.0);
  auxiliary_point[8] = getAuxiliaryPoint(v[2], v[0], 7.0/8.0, -1.0/30.0);
  auxiliary_point[9] = getAuxiliaryPoint(v[2], v[0], 1.0, -1.0/30.0);
  tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  tri.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
  tri.bezierVertex(auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y);
  tri.quadraticVertex(auxiliary_point[7].x, auxiliary_point[7].y, auxiliary_point[8].x, auxiliary_point[8].y);
  tri.quadraticVertex(auxiliary_point[9].x, auxiliary_point[9].y, v[0].x, v[0].y);  

  tri.endShape();
  
  return tri;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileP2(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){    
    PShape tri = transformTriangle(); // 変形した三角形の生成
    tri.rotate(PI * i); // 180度回転
    tile.addChild(tri); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      tile.resetMatrix();
      tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
      shape(tile); // タイルを描画
    }
  }
  
  // 格子点を描く
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}