ここでは、アイソヘドラルタイリングIH79(P4)について、解説します。
IH79(P4)
アイソヘドラルタイリングIH79(P4)の基本図形は以下のような形になります。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/IH79_P4_FundamentalbeforeTransformation.jpg)
これは、記事「基本図形の形を考える」で示したP4群の基本図形の各辺の長さを調整したものになっています。
IH79(P4)の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/538a7db14d92eea980fe1b3232f83c5b.jpg)
今回、基本図形は直角二等辺三角形の形状をしています。直角二等辺三角形の直角でない2つの頂点がそれぞれ正方格子点(黒点)と一致するようにとります。直角二等辺三角形の直角となるが近接する4つの正方格子点で作られる正方形の重心(赤点)と一致するようにとります。
IH79(P4)の基本図形を並べる
このIH79(P4)の基本図形をP4群の対称性を保ちながら並べると、以下のような図形が得られます。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/IH79_P4.jpg)
IH79(P4)の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/009e5a3399984420163091a3050e8a21.jpg)
辺\(a\)と辺\(b\)は互いに異なる向きに重なっています。つまり、辺\(a\)を変形し、辺\(b\)は辺\(a\)と同じ形で上下左右反転した形に変形します。辺\(c\)は両側のラベルが同じで異なる向きに重なっています。つまり、辺\(c\)は中点に対して点対称に変形することができます。それにより、隣り合う基本図形同士を重ねることなくP4群の対称性に従って敷き詰めることができます。
ここでは、書籍「装飾パターンの法則」のp.105にあるIH79(P4)の例を参考に、このルールに従ってIH79(P4)の基本図形を下図のように変形してみました。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/IH79_P4_FundamentalafterTransformation.jpg)
この変形した基本図形をP4群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は正方格子点も示しています。
![](https://www.mathartroom.com/wp-content/uploads/2022/10/IH79_P4_transformation.jpg)
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeSquareVector(); // 正方格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP4(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH79_P4_transformation.jpg");
}
// 正方格子を張るベクトルを生成する関数
void makeSquareVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = new PVector(0.0, 1.0);
}
// 正方格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].y); // 行の数
lattice = new PVector[col_num + 1][row_num + 1];
for (int i = 0; i < col_num + 1; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x, v.y);
}
}
}
// 三角形を変形する関数(基本図形)
PShape transformTriangle(){
PVector[] v = new PVector[3]; // 三角形の頂点
v[0] = new PVector(0.0, 0.0);
v[1] = new PVector(scalar / 2.0, scalar / 2.0);
v[2] = base[0].copy().mult(scalar);
// 三角形を変形する
PShape tri = createShape();
tri.beginShape();
PVector[] auxiliary_point = new PVector[20];
// 辺aを変形する
tri.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/16.0, 3.0/32.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 5.0/32.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 5.0/32.0, -3.0/32.0);
auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 3.0/16.0, -3.0/16.0);
auxiliary_point[4] = getAuxiliaryPoint(v[0], v[1], 13.0/64.0, -1.0/16.0);
auxiliary_point[5] = getAuxiliaryPoint(v[0], v[1], 7.0/32.0, -1.0/64.0);
auxiliary_point[6] = getAuxiliaryPoint(v[0], v[1], 15.0/64.0, -1.0/16.0);
auxiliary_point[7] = getAuxiliaryPoint(v[0], v[1], 1.0/4.0, -5.0/32.0);
auxiliary_point[8] = getAuxiliaryPoint(v[0], v[1], 17.0/64.0, -1.0/16.0);
auxiliary_point[9] = getAuxiliaryPoint(v[0], v[1], 17.0/64.0, 0.0);
auxiliary_point[10] = getAuxiliaryPoint(v[0], v[1], 2.0/3.0, 1.0/16.0);
auxiliary_point[11] = getAuxiliaryPoint(v[0], v[1], 31.0/32.0, -3.0/16.0);
auxiliary_point[12] = getAuxiliaryPoint(v[0], v[1], 1.0, -3.0/16.0);
auxiliary_point[13] = getAuxiliaryPoint(v[0], v[1], 17.0/16.0, 0.0);
tri.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
tri.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
tri.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y);
tri.quadraticVertex(auxiliary_point[7].x, auxiliary_point[7].y, auxiliary_point[8].x, auxiliary_point[8].y);
tri.bezierVertex(auxiliary_point[9].x, auxiliary_point[9].y, auxiliary_point[10].x, auxiliary_point[10].y, auxiliary_point[11].x, auxiliary_point[11].y);
tri.bezierVertex(auxiliary_point[12].x, auxiliary_point[12].y, auxiliary_point[13].x, auxiliary_point[13].y, v[1].x, v[1].y);
// 辺bを辺aと同じ形で上下左右反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], -1.0/16.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 0.0, 3.0/16.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 1.0/32.0, 3.0/16.0);
auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 1.0/3.0, -1.0/16.0);
auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 47.0/64.0, 0.0);
auxiliary_point[5] = getAuxiliaryPoint(v[1], v[2], 47.0/64.0, 1.0/16.0);
auxiliary_point[6] = getAuxiliaryPoint(v[1], v[2], 3.0/4.0, 5.0/32.0);
auxiliary_point[7] = getAuxiliaryPoint(v[1], v[2], 49.0/64.0, 1.0/16.0);
auxiliary_point[8] = getAuxiliaryPoint(v[1], v[2], 25.0/32.0, 1.0/64.0);
auxiliary_point[9] = getAuxiliaryPoint(v[1], v[2], 51.0/64.0, 1.0/16.0);
auxiliary_point[10] = getAuxiliaryPoint(v[1], v[2], 13.0/16.0, 3.0/16.0);
auxiliary_point[11] = getAuxiliaryPoint(v[1], v[2], 27.0/32.0, 3.0/32.0);
auxiliary_point[12] = getAuxiliaryPoint(v[1], v[2], 27.0/32.0, 0.0);
auxiliary_point[13] = getAuxiliaryPoint(v[1], v[2], 15.0/16.0, -3.0/32.0);
tri.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
tri.bezierVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[5].x, auxiliary_point[5].y);
tri.quadraticVertex(auxiliary_point[6].x, auxiliary_point[6].y, auxiliary_point[7].x, auxiliary_point[7].y);
tri.quadraticVertex(auxiliary_point[8].x, auxiliary_point[8].y, auxiliary_point[9].x, auxiliary_point[9].y);
tri.quadraticVertex(auxiliary_point[10].x, auxiliary_point[10].y, auxiliary_point[11].x, auxiliary_point[11].y);
tri.bezierVertex(auxiliary_point[12].x, auxiliary_point[12].y, auxiliary_point[13].x, auxiliary_point[13].y, v[2].x, v[2].y);
// 辺cを中点に対して点対称に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[0], 1.0/16.0, 1.0/16.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[0], 1.0/8.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[0], 7.0/16.0, -1.0/3.0);
auxiliary_point[3] = getAuxiliaryPoint(v[2], v[0], 9.0/16.0, 1.0/3.0);
auxiliary_point[4] = getAuxiliaryPoint(v[2], v[0], 7.0/8.0, 0.0);
auxiliary_point[5] = getAuxiliaryPoint(v[2], v[0], 15.0/16.0, -1.0/16.0);
tri.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
tri.bezierVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
tri.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, v[0].x, v[0].y);
tri.endShape();
return tri;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP4(){
tile = createShape(GROUP); // PShapeのグループを作る
for(int i=0; i<4; i++){
PShape square = transformTriangle(); // 変形した三角形の生成
square.rotate(i*radians(90)); // 三角形の位置を調整
tile.addChild(square); // グループに追加
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
// 格子点を描く
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}