IH73（P4G）

ここでは、アイソヘドラルタイリングIH73（P4G）について、解説します。

Contents

1 IH73（P4G）
- 1.1 IH73（P4G）の基本図形のサイズ
- 1.2 IH73（P4G）の基本図形を並べる
2 IH73（P4G）の基本図形の変形
- 2.1 ※辺\(a\)と辺\(b\)の変形について
3 プログラムコード

アイソヘドラルタイリングIH73（P4G）の基本図形は以下のような形になります。

これは、記事「基本図形の形を考える」で示したP4G群の基本図形の各辺の長さを調整したものを8つ組み合わせたものになっています。

IH73（P4G）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

今回、基本図形は正方形の形状をしています。正方形の4つの頂点、正方形の各辺の中点、および正方形の重心がそれぞれ正方格子点（黒点）と一致するようにとります。なお、正方形を図のように点線で分けると、8つのP4G群の基本図形となります。

IH73（P4G）の基本図形を並べる

このIH73（P4G）の基本図形をP4G群の対称性を保ちながら並べると、以下のような図形が得られます。

IH73（P4G）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

正方形の対辺はそれぞれ同じ辺となります。

辺\(a\)と辺\(b\)が重なっていますが、今回、向きは両方に取っています。これは、辺\(a\)をその垂直二等分線に対して線対称になるように変形し、辺\(b\)は変形した辺\(a\)を上下反転した形状に変形します。

※辺\(a\)と辺\(b\)の変形について

『辺\(a\)をその垂直二等分線に対して線対称になるように変形する』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH73（P4G）の基本図形を記事「基本図形の形を考える」で示したP4G群の基本図形に分けて考えてみます。

このとき、辺\(a\)は２つの辺\(a’\)、辺\(b\)は２つの辺\(b’\)にそれぞれ分けられます。辺\(a\)は辺\(a’\)を異なる向きに2つ並べたものになっていますので、辺\(a\)の変形はその垂直二等分線に対して線対称になります。一方、辺\(a’\)と辺\(b’\)が異なる向きに重なっています。これは辺\(a’\)を変形し、辺\(b’\)は変形した辺\(a’\)を上下左右反転した形状に変形することを表しています。つまり、辺\(b\)は変形した辺\(a\)を上下反転した形状に変形すればよいことが分かります。

ここでは、書籍「装飾パターンの法則」のp.104にあるIH73（P4G）の例を参考に、このルールに従ってIH73（P4G）の基本図形を下図のように変形してみました。

この変形した基本図形をP4G群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は正方格子点も示しています。

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeSquareVector(); // 正方格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP4G(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH73_P4G_transformation.jpg");
}

// 正方格子を張るベクトルを生成する関数
void makeSquareVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = new PVector(0.0, 1.0);
}

// 正方格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 1][row_num + 1];
  for (int i = 0; i < col_num + 1; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x, v.y);
    }
  }
}

// 正方形を変形する関数（基本図形）
PShape transformSquare(){
  
  PVector[] v = new PVector[4]; // 正方形の頂点

  v[0] = base[1].copy().mult(2.0 * scalar);
  v[1] = base[0].copy().mult(2.0 * scalar);
  v[1].add(base[1].copy().mult(2.0 * scalar));
  v[2] = base[0].copy().mult(2.0 * scalar);
  v[3] = new PVector(0.0, 0.0);

  // 正方形を変形する
  PShape square = createShape();
  square.beginShape(); 
  PVector[] auxiliary_point = new PVector[3];
  // 辺aを垂直二等分線に対して線対称に変形する。
  square.vertex(v[0].x, v[0].y);
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/3.0, 0.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, sqrt(3.0)/6.0); 
  auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 2.0/3.0, 0.0); 
  square.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  square.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
  square.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
  square.vertex(v[1].x, v[1].y);  
  // 辺bは辺aと同じ形で上下反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/3.0, 0.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, -sqrt(3.0)/6.0); 
  auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 2.0/3.0, 0.0); 
  square.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  square.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
  square.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
  square.vertex(v[2].x, v[2].y);
  // もう1つの辺aを変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/3.0, 0.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, sqrt(3.0)/6.0); 
  auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 2.0/3.0, 0.0); 
  square.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  square.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
  square.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
  square.vertex(v[3].x, v[3].y);  
  // もう1つの辺bを変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[3], v[0], 1.0/3.0, 0.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[3], v[0], 1.0/2.0, -sqrt(3.0)/6.0); 
  auxiliary_point[2] = getAuxiliaryPoint(v[3], v[0], 2.0/3.0, 0.0); 
  square.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  square.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
  square.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
  square.vertex(v[0].x, v[0].y);  

  square.endShape();
  
  return square;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileP4G(){
  tile = createShape(GROUP); // PShapeのグループを作る
    for(int i=0; i<4; i++){
      PShape square = transformSquare(); // 変形した正方形の生成 
      square.rotate(i*radians(90)); // 正方形の回転
      tile.addChild(square); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%4 == 0 && j%4==0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画 
      }
    }
  }

  // 格子点を描く
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}