IH41（P1）

  1. ホーム
  2. 壁紙アート
  3. アイソヘドラルタイリング
  4. IH41（P1）

ここでは、アイソヘドラルタイリングIH41（P1）について、解説します。

IH41（P1）

アイソヘドラルタイリングIH41（P1）の基本図形は以下のような形になります。

IH41（P1）の基本図形

これは、記事「基本図形の形を考える」で示したP1群の基本図形の各辺の長さを調整したものになっています。また、一般格子のサイズ、方向についても調整しています。

IH41（P1）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

IH41（P1）の基本図形のサイズ

今回、基本図形として平行四辺形をとります。また、平行四辺形の各頂点は近接する一般格子点と一致するようにとります。

IH41（P1）の基本図形を並べる

このIH41（P1）の基本図形をP1群の対称性を保ちながら並べると、以下のような図形が得られます。

IH41（P1）による図形

IH41（P1）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

IH41（P1）の基本図形に対する辺のラベルと向き

辺\(a\)と辺\(c\)、および辺\(b\)と辺\(d\)がそれぞれ異なる向きに重なっています。つまり、辺\(a\)を変形し、辺\(c\)は変形した辺\(a\)を上下左右反転した形状に変形します。辺\(b\)と辺\(d\)も同様に変形します。それにより、隣り合う基本図形同士を重ねることなくP1群の対称性に従って敷き詰めることができます。

ここでは、書籍「装飾パターンの法則」のp.100にあるIH41（P1）の例を参考に、このルールに従ってIH41（P1）の基本図形を下図のように変形してみました。

IH41（P1）の基本図形の変形

この変形した基本図形をP1群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は一般格子点も示しています。

IH41（P1）の変形した基本図形による図形

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 6; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeGeneralVector(); // 一般格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP1(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH41_P1_transformation.jpg");
}

// 一般格子を張るベクトルを生成する関数
void makeGeneralVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI * 7.0 / 12.0);
  base[1].mult(0.8);
}

// 一般格子を生成する関数
void makeLattice(){
  int row_num;
  if( abs(base[1].x) < 1.0e-6 ){
    row_num = col_num;
  } else {
    row_num = ceil(col_num / abs(base[1].x)); // 行の数
  }
  lattice = new PVector[col_num + 3][row_num + 1];
  for (int i = 0; i < col_num + 3; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+3)*scalar), v.y); 
    }
  }
}

// 四角形を変形する関数（基本図形）
PShape transformRectangle(){
  
  PVector[] v = new PVector[4]; // 四角形の頂点

  v[0] = new PVector(0.0, 0.0);
  v[1] = base[0].copy().mult(scalar);
  v[2] = v[1].copy();
  v[2].sub(base[1].copy().mult(scalar));
  v[3] = base[1].copy().mult(-scalar);

  // 四角形を変形する
  PShape rect = createShape();
  rect.beginShape(); 
  PVector[] auxiliary_point = new PVector[10];
  // 辺aを変形する
  rect.vertex(v[0].x, v[0].y);
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/40.0, 1.0/10.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/20.0, 1.0/10.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 5.0/12.0, 1.0/40.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 11.0/24.0, 0.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[0], v[1], 11.0/24.0, -1.0/8.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, -1.0/4.0);
  auxiliary_point[6] = getAuxiliaryPoint(v[0], v[1], 7.0/12.0, -1.0/8.0);
  auxiliary_point[7] = getAuxiliaryPoint(v[0], v[1], 5.0/6.0, -9.0/40.0);
  auxiliary_point[8] = getAuxiliaryPoint(v[0], v[1], 11.0/12.0, -1.0/4.0);
  rect.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  rect.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
  rect.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
  rect.bezierVertex(auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y, auxiliary_point[7].x, auxiliary_point[7].y);
  rect.quadraticVertex(auxiliary_point[8].x, auxiliary_point[8].y, v[1].x, v[1].y);
  // 辺bを変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/40.0, 1.0/10.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/20.0, 1.0/10.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 5.0/12.0, -1.0/20.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, -1.0/10.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 8.0/9.0, -1.0/6.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[1], v[2], 17.0/18.0, -1.0/6.0);
  rect.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  rect.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
  rect.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
  rect.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, v[2].x, v[2].y);
  // 辺cを辺aと同じ形で上下左右反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/12.0, 1.0/4.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0/6.0, 9.0/40.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 5.0/12.0, 1.0/8.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, 1.0/4.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[2], v[3], 13.0/24.0, 1.0/8.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[2], v[3], 13.0/24.0, 0.0);
  auxiliary_point[6] = getAuxiliaryPoint(v[2], v[3], 7.0/12.0, -1.0/40.0);
  auxiliary_point[7] = getAuxiliaryPoint(v[2], v[3], 19.0/20.0, -1.0/10.0);
  auxiliary_point[8] = getAuxiliaryPoint(v[2], v[3], 39.0/40.0, -1.0/10.0);
  rect.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  rect.bezierVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
  rect.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y);
  rect.vertex(auxiliary_point[7].x, auxiliary_point[7].y);
  rect.quadraticVertex(auxiliary_point[8].x, auxiliary_point[8].y, v[3].x, v[3].y);
  // 辺dを辺bと同じ形で上下左右反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[3], v[0], 1.0/18.0, 1.0/6.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[3], v[0], 1.0/9.0, 1.0/6.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[3], v[0], 1.0/2.0, 1.0/10.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[3], v[0], 7.0/12.0, 1.0/20.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[3], v[0], 19.0/20.0, -1.0/10.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[3], v[0], 39.0/40.0, -1.0/10.0);
  rect.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  rect.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
  rect.vertex(auxiliary_point[4].x, auxiliary_point[4].y);
  rect.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, v[0].x, v[0].y);
  
  rect.endShape();
  
  return rect;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileP1(){
  tile = createShape(GROUP); // PShapeのグループを作る
  PShape rect = transformRectangle(); // 変形後の基本図形の生成
  tile.addChild(rect); // グループに追加
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      tile.resetMatrix();
      tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
      shape(tile); // タイルを描画
    }
  }

  // 格子点を描く
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}

コメントを残す