ここでは、アイソヘドラルタイリングIH29（P4G）について、解説します。
Contents
IH29（P4G）
アイソヘドラルタイリングIH29（P4G）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したP4G群の基本図形の各辺の長さを調整したものを2つ組み合わせたものになっています。
IH29（P4G）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
今回、辺\(b, b’ , c, c’\)は同じ長さを持つように設定します。
IH29（P4G）の基本図形は五角形で、上図のように点線で2つの四角形に分けると、各四角形は記事「基本図形の形を考える」で示したP4G群の基本図形の各辺の長さを調整したものであり、2つの四角形は点線でお互いに線対称になっています。
今回、辺\(a\)の中点と辺\(b\)と辺\(c\)の交点、および辺\(b’\)と辺\(c’\)の交点は、近接す正方格子点（黒点）の並びとなるように設定します。あとは、上図の\(r_1\)を適当に調整することで基本図形の形を決めることができます。
IH29（P4G）の基本図形を並べる
このIH29（P4G）の基本図形をP4G群の対称性を保ちながら並べると、以下のような図形が得られます。
IH29（P4G）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
辺\(b\)と辺\(b’\)、および辺\(c\)と辺\(c’\)はそれぞれ同じ辺となります。
辺\(a\)については今回変形できません。これは下で説明します。辺\(b\)と辺\(c\)は異なる向きになっています。これは、辺\(b\)を変形し、辺\(c\)は変形した辺\(b\)と同じ形を上下左右反転した形に変形します。これらの変形により、隣り合う基本図形同士を重ねることなくP4G群の対称性に従って敷き詰めることができます。
※辺\(a\)の変形について
『辺\(a\)が変形できない』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH29（P4G）の基本図形を記事「基本図形の形を考える」で示したP4G群の基本図形に分けて考えてみます。
このとき、辺\(a\)は２つの辺\(a′\)に分けられます。辺\(a\)は辺\(a′\)を異なる向きに2つ並べたものになっていますので、辺\(a\)の変形は垂直二等分線（ここでは点線）に対して線対称になることになります。一方、辺\(a′\)の両側のラベルは同じで同じ向きに重なっています。これは辺\(a′\)が変形できないことを示しています。つまり、辺\(a\)は変形できないことが分かります。
ここでは、書籍「装飾パターンの法則」のp.98にあるIH29（P4G）の例を参考に、このルールに従ってIH29（P4G）の基本図形を下図のように変形してみました。
この変形した基本図形をP4G群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は正方格子点も示しています。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 6; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeSquareVector(); // 正方格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP4G(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH29_P4G_transformation.jpg");
}
// 正方格子を張るベクトルを生成する関数
void makeSquareVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = new PVector(0.0, 1.0);
}
// 正方格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].y); // 行の数
lattice = new PVector[col_num + 1][row_num + 1];
for (int i = 0; i < col_num + 1; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x, v.y);
}
}
}
// 五角形を変形する関数（基本図形）
PShape transformPentagon(){
PVector[] v = new PVector[5]; // 五角形の頂点
float r1;
r1 = 2.0/11.0 * scalar;
v[0] = new PVector(-r1, -r1);
v[1] = new PVector(r1, r1);
v[2] = base[0].copy().mult(scalar);
v[3] = new PVector(-r1, r1);
v[3].add(base[0].copy().mult(scalar));
v[3].sub(base[1].copy().mult(scalar));
v[4] = base[1].copy().mult(-scalar);
// 五角形を変形する
PShape pentagon = createShape();
pentagon.beginShape();
PVector[] auxiliary_point = new PVector[11];
// 辺aは変形しない
pentagon.vertex(v[0].x, v[0].y);
pentagon.vertex(v[1].x, v[1].y);
// 辺bを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/20.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/10.0, 1.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 1.0/10.0, -2.0/3.0);
pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
pentagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[2].x, v[2].y);
// 辺cは辺bと同じ形で上下左右反転したものに変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 9.0/10.0, 2.0/3.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 9.0/10.0, -1.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 19.0/20.0, 0.0);
pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
pentagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[3].x, v[3].y);
// 辺c'を辺cと同じ形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 1.0/20.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[3], v[4], 1.0/10.0, -1.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[3], v[4], 1.0/10.0, 2.0/3.0);
pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
pentagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[4].x, v[4].y);
// 辺b'を辺bと同じ形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[4], v[0], 9.0/10.0, -2.0/3.0);
auxiliary_point[1] = getAuxiliaryPoint(v[4], v[0], 9.0/10.0, 1.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[4], v[0], 19.0/20.0, 0.0);
pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
pentagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[0].x, v[0].y);
pentagon.endShape();
return pentagon;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP4G(){
tile = createShape(GROUP); // PShapeのグループを作る
for(int j=0; j<2; j++){
for(int i=0; i<2; i++){
PShape pentagon = transformPentagon(); // 変形した五角形の生成
pentagon.scale(1, pow(-1,i)); // 五角形の反転
pentagon.rotate(i*radians(90)+j*radians(90)); // 五角形の回転
pentagon.translate(j*scalar, j*scalar); // 五角形の位置を調整
tile.addChild(pentagon); // グループに追加
}
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( i%2 == 0 && j%2==0 ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
// 格子点を描く
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}