ここでは、アイソヘドラルタイリングIH21（P6）について、解説します。
IH21（P6）
アイソヘドラルタイリングIH21（P6）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したP6群の基本図形の各辺の長さを調整したものになっています。
IH21（P6）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
今回、辺\(b\)と辺\(c\)、辺\(d\)と辺\(e\)は、それぞれ同じ長さを持つように設定します。また、辺\(a\)の中点と、辺\(b\)と辺\(c\)の交点はそれぞれ近接する２つの三角格子点（黒点）と一致するようにとり、辺\(d\)と辺\(e\)の交点は近接する3つの三角格子の重心（赤点）と一致するようにとります。さらに、辺\(b\)と辺\(c\)の間の角を60°、辺\(d\)と辺\(e\)の間の角を120°にとります。あとは、\(r_1, r_2\)の長さを適当に調整することで、この基本図形の形を決めることができます。
IH21（P6）の基本図形を並べる
このIH21（P6）の基本図形をP6群の対称性を保ちながら並べると、以下のような図形が得られます。
IH21（P6）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
辺\(a\)は両側のラベルが同じで異なる向きに重なっていますので、辺\(a\)はその中点に対して点対称になるように変形します。辺\(b\)と辺\(c\)、辺\(d\)と辺\(e\)がそれぞれ異なる向きに重なっています。つまり、辺\(b\)を変形し、辺\(c\)は、変形した辺\(b\)を上下左右反転した形状に変形します。辺\(d\)と辺\(e\)についても同様な変形を行うことができます。それにより、隣り合う基本図形同士を重ねることなくP6群の対称性に従って敷き詰めることができます。
ここでは、書籍「装飾パターンの法則」のp.97にあるIH21（P6）の例を参考に、このルールに従ってIH21（P6）の基本図形を下図のように変形してみました。
この変形した基本図形をP6群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeTriangleVector(); // 三角格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP6(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH21_P6_transformation.jpg");
}
// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = PVector.fromAngle(PI / 3);
}
// 三角格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].x); // 行の数
lattice = new PVector[col_num + 3][row_num + 1];
for (int i = 0; i < col_num + 3; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x % ((col_num+3)*scalar) - 2 * scalar, v.y); // x軸方向にscalarの2倍だけ左にシフト
}
}
}
// 五角形を変形する関数（基本図形）
PShape transformPentagon(){
PVector[] v = new PVector[5]; // 五角形の頂点
float r1, r2;
r1 = 1.0/6.0 * scalar;
r2 = 1.0/12.0 * scalar;
v[0] = new PVector(-r2, -r1);
v[0].sub(base[0].copy().mult(scalar));
v[1] = new PVector(r2, r1);
v[1].sub(base[0].copy().mult(scalar));
v[2] = new PVector(0.0, 0.0);
v[3] = v[1].copy().rotate(radians(60));
v[4] = new PVector(0.0, -2.0 / 3.0 * base[1].y * scalar);
v[4].sub(base[0].copy().mult(scalar));
// 五角形を変形する
PShape pentagon = createShape();
pentagon.beginShape();
PVector[] auxiliary_point = new PVector[11];
// 辺aは中点に対して点対称に変形する
pentagon.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/8.0, 3.0/16.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/4.0, 1.0/4.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 3.0/4.0, -1.0/4.0);
auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 7.0/8.0, -3.0/16.0);
pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
pentagon.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
pentagon.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, v[1].x, v[1].y);
// 辺bを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 2.0/5.0, 3.0/32.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, 1.0/8.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 9.0/10.0, -1.0/8.0);
auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 15.0/16.0, -1.0/32.0);
auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 31.0/32.0, -1.0/32.0);
pentagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
pentagon.bezierVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y);
pentagon.quadraticVertex(auxiliary_point[4].x, auxiliary_point[4].y, v[2].x, v[2].y);
// 辺cは辺bと同じ形を上下左右反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/32.0, 1.0/32.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0/16.0, 1.0/32.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 1.0/10.0, 1.0/8.0);
auxiliary_point[3] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, -1.0/8.0);
auxiliary_point[4] = getAuxiliaryPoint(v[2], v[3], 3.0/5.0, -3.0/32.0);
pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
pentagon.bezierVertex(auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
pentagon.vertex(v[3].x, v[3].y);
// 辺dを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 1.0/3.0, 1.0/2.0);
auxiliary_point[1] = getAuxiliaryPoint(v[3], v[4], 1.0/2.0, 1.0/3.0);
pentagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
pentagon.vertex(v[4].x, v[4].y);
// 辺cは辺bと同じ形を上下左右反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[4], v[0], 1.0/2.0, -1.0/3.0);
auxiliary_point[1] = getAuxiliaryPoint(v[4], v[0], 2.0/3.0, -1.0/2.0);
pentagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
pentagon.quadraticVertex(auxiliary_point[1].x, auxiliary_point[1].y, v[0].x, v[0].y);
pentagon.endShape();
return pentagon;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( i%2 == 0 && j%2 == 0 ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
// 格子点を描画する
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}