ランダムドット・ステレオグラム

float k = 500.0; // 座標原点から紙までの距離
float m = 500.0; // 紙から目までの距離
float h = 100.0; // 目と目の間の距離の半分
  
float s = 400.0; // ランダムドット・ステレオグラムで作る正四面体の一辺の長さ

void setup(){
  size(500,600,P2D);
  background(255,255,255);
  
  PVector point3d; // 立体視したい図形上の点
  float x_r, x_l, y_eye; // 紙上の点
  
  float triangular_pyramid_size = 50.0; // 三角錐のサイズ
  // 三角錐の4つの頂点のベクトル
  PVector triangular_pyramid[] = new PVector[4];
  triangular_pyramid[0] = new PVector(0.0, 0.0, sqrt(2.0/3.0)*triangular_pyramid_size);
  triangular_pyramid[1] = new PVector(0.0, -1.0/sqrt(3.0)*triangular_pyramid_size, 0.0);
  triangular_pyramid[2] = triangular_pyramid[1].copy().rotate(radians(120));
  triangular_pyramid[3] = triangular_pyramid[1].copy().rotate(radians(240)); 

  translate(width/2, 50);

  // 紙の上に三角錐を左目用と右目用にそれぞれ射影する

  for(int i=0; i<4; i++){
    for(int j=i+1; j<4; j++){
      for(int d=0; d<100; d++){
        point3d = triangular_pyramid[i].copy().add(triangular_pyramid[j].copy().sub(triangular_pyramid[i].copy()).mult(d/100.0)); 
        x_r = (m * point3d.x - h * point3d.z + h*k) / (m + k - point3d.z);
        x_l = (m * point3d.x + h * point3d.z - h*k) / (m + k - point3d.z);
        y_eye = m * point3d.y / (m + k - point3d.z);
        point(x_r, y_eye);
        point(x_l, y_eye);
      }
    }
  }
  translate(0, 300);

  float x_ini, y_ini;  
  for(int i=0; i<2000; i++){
    colorMode(HSB);
    fill(random(360),100,1000);      
    noStroke();
   
    x_ini = random(width)-width/2; // 紙上の点の初期値x座標
    y_ini = random(width)-width/2; // 紙上の点の初期値y座標

    // まず初期値が左目からの座標として処理する
    x_l = x_ini;
    y_eye = y_ini;
    ellipse(x_l, y_eye, 5, 5);
    while(true){
      // この左目からの位置に対応する対称物体の上の点の位置を算出する。
      point3d = get3DPoint(x_l, y_eye, -h);
      // この対称物体上の点に対応する、右目からの紙上の座標位置を算出する。
      x_r = (m * point3d.x - h * point3d.z + h * k) / (m + k - point3d.z);
      if( abs(x_r) < width/2.0 ){ 
        ellipse(x_r, y_eye, 5, 5);
        x_l = x_r;
      } else {
        break;
      }
    }
    
    // 次に初期値を右目からの座標として処理する
    x_r = x_ini;
    while(true){
      // この右目からの位置に対応する対称物体の上の点の位置を算出する。
      point3d = get3DPoint(x_r, y_eye, h);
      // この対称物体上の点に対応する、左目からの紙上の座標位置を算出する。
      x_l = (m * point3d.x + h * point3d.z - h * k) / (m + k - point3d.z);
      if( abs(x_l) < width/2.0 ){ 
        ellipse(x_l, y_eye, 5, 5);
        x_r = x_l;
      } else {
        break;
      }
    }    
  }
      
  save("stereogram_triangular_pyramid_randomdot.jpg");
  
}

// 対称物体上の点の位置を算出する関数
PVector get3DPoint(
  float x_on_paper, // 紙上の点のx座標
  float y_on_paper, // 紙上の点のy座標
  float eye_pos_x // 左目の場合-h, 右目の場合h
){
  // 視点（左目or右目）と紙上の点を通る直線をパラメータ表示したときの係数
  float ax = x_on_paper - eye_pos_x;
  float bx = eye_pos_x;
  float ay = y_on_paper;
  float by = 0.0;
  float az = -m;
  float bz = m + k;

  float t1, t2, t3;
  float x, y, z;
  // 視線と正四面体の交点が△OBCに含まれるか
  t1 = (k+m-sqrt(2.0/3.0)*s)/(-2.0*sqrt(2.0) * y_on_paper + m);
  x = ax * t1 + bx;
  y = ay * t1 + by;
  z = az * t1 + bz;
  if( z < 0.0
    || x/sqrt(3.0)+y < 0.0
    || -x/sqrt(3.0)+y < 0.0
  ){
    t1 = (m+k)/m;
  }
  
  // 視線と正四面体の交点が△OABに含まれるか
  t2 = ((k+m-sqrt(2.0/3.0)*s)/sqrt(2.0) - sqrt(3.0)*eye_pos_x)/(sqrt(3.0)*(x_on_paper - eye_pos_x) + y_on_paper + m / sqrt(2.0));
  x = ax * t2 + bx;
  y = ay * t2 + by;
  z = az * t2 + bz;
  if( z < 0.0 
    || x > 0.0
    || x/sqrt(3.0)+y > 0.0
  ){
    t2 = (m+k)/m;
  }
  
  // 視線と正四面体の交点が△OCAに含まれるか
  t3 = ((k+m-sqrt(2.0/3.0)*s)/sqrt(2.0) + sqrt(3.0)*eye_pos_x)/(-sqrt(3.0)*(x_on_paper - eye_pos_x) + y_on_paper + m / sqrt(2.0));
  x = ax * t3 + bx;
  y = ay * t3 + by;
  z = az * t3 + bz;
  if( z < 0.0
    || -x/sqrt(3.0)+y > 0.0
    || x < 0.0
  ){
    t3 = (m+k)/m;
  }

  // 対称物体上の点の位置を算出
  float t = t1;
  if( t > t2 ){
    t = t2;
  }
  if( t > t3 ){
    t = t3;
  }
  x = ax * t + bx;
  y = ay * t + by;
  z = az * t + bz;

  PVector result = new PVector(x,y,z);
  return result;
}